|| apoc.refactor.cloneSubgraphFromPaths - APOC Core 文档 - Neo4j 文档

apoc.refactor.cloneSubgraphFromPaths

详情
语法	`apoc.refactor.cloneSubgraphFromPaths(paths [, config ]) :: (input, output, error)`
描述	克隆由给定 `LIST<PATH>` 值定义的子图。可以使用 `config MAP` 中的 `skipProperties LIST<STRING>` 跳过任何 `NODE` 属性。
输入参数	名称	类型	描述
	`paths`	`LIST<PATH>`	要克隆的路径。
	`config`	`MAP`	`{ standinNodes :: LIST<LIST<NODE>>, skipProperties :: LIST<STRING> }`。默认值为：`{}`。
返回参数	名称	类型	描述
	`input`	`INTEGER`	原始实体的内部 ID。
	`output`	`NODE`	复制的实体。
	`error`	`STRING`	复制过程中发生的任何错误。

使用示例

本节中的示例基于以下示例图

CREATE  (rootA:Root{name:'A'}),
        (rootB:Root{name:'B'}),
        (n1:Node{name:'node1', id:1}),
        (n2:Node{name:'node2', id:2}),
        (n3:Node{name:'node3', id:3}),
        (n4:Node{name:'node4', id:4}),
        (n5:Node{name:'node5', id:5}),
        (n6:Node{name:'node6', id:6}),
        (n7:Node{name:'node7', id:7}),
        (n8:Node{name:'node8', id:8}),
        (n9:Node{name:'node9', id:9}),
        (n10:Node{name:'node10', id:10}),
        (n11:Node{name:'node11', id:11}),
        (n12:Node{name:'node12', id:12})
        CREATE (rootA)-[:LINK]->(n1)-[:LINK]->(n2)-[:LINK]->(n3)-[:LINK]->(n4)
        CREATE                  (n1)-[:LINK]->(n5)-[:LINK]->(n6)<-[:LINK]-(n7)
        CREATE                                (n5)-[:LINK]->(n8)
        CREATE                                (n5)-[:LINK]->(n9)-[:DIFFERENT_LINK]->(n10)
        CREATE (rootB)-[:LINK]->(n11);

图 1. 子图克隆前的图

此过程克隆由路径列表定义的子图。当您想要确保克隆的子图未连接到原始节点或子图外部的节点时，此功能非常有用。

以下查询克隆了一个从 rootA 开始的子树，该子树包含传出的 :LINK 关系，并将该子图附加到 rootB。rootB 作为 rootA 的替代，rootA 不会被克隆。

MATCH  (rootA:Root{name:'A'}),
       (rootB:Root{name:'B'})
MATCH path = (rootA)-[:LINK*]->(node)
WITH rootA, rootB, collect(path) as paths
CALL apoc.refactor.cloneSubgraphFromPaths(paths, {
    standinNodes:[[rootA, rootB]]
})
YIELD input, output, error
RETURN input, output, error;

结果
input	output	error
31424	(:Node {name: "node3", id: 3})	NULL
31425	(:Node {name: "node4", id: 4})	NULL
31426	(:Node {name: "node5", id: 5})	NULL
31427	(:Node {name: "node6", id: 6})	NULL
31429	(:Node {name: "node8", id: 8})	NULL
31430	(:Node {name: "node9", id: 9})	NULL
31422	(:Node {name: "node1", id: 1})	NULL
31423	(:Node {name: "node2", id: 2})	NULL

apoc.refactor.cloneSubgraphFromPaths after

图 2. 子图克隆后的图