|| apoc.neighbors.tohop.count - APOC 核心文档 - Neo4j 文档

apoc.neighbors.tohop.count

详情
语法	`apoc.neighbors.tohop.count(node [, relTypes, distance ]) :: (value)`
描述	返回在指定距离内，由给定 `RELATIONSHIP` 值在模式中连接的所有 `NODE` 值的计数。
输入参数	名称	类型	描述
	`node`	`NODE`	算法的起始节点。
	`relTypes`	`STRING`	要遵循的关系类型列表。关系类型使用 APOC 的关系方向模式语法表示；`[<]RELATIONSHIP_TYPE1[>]\|[<]RELATIONSHIP_TYPE2[>]\|…`。默认值为：``。
	`distance`	`INTEGER`	要跳过的最大跳数。默认值为：`1`。
返回参数	名称	类型	描述
返回参数	`value`	`INTEGER`	给定跳数距离内邻近节点的总计数。

使用示例

本节中的示例基于以下示例图

MERGE (mark:Person {name: "Mark"})
MERGE (praveena:Person {name: "Praveena"})
MERGE (joe:Person {name: "Joe"})
MERGE (lju:Person {name: "Lju"})
MERGE (michael:Person {name: "Michael"})
MERGE (emil:Person {name: "Emil"})
MERGE (ryan:Person {name: "Ryan"})

MERGE (ryan)-[:FOLLOWS]->(joe)
MERGE (joe)-[:FOLLOWS]->(mark)
MERGE (mark)-[:FOLLOWS]->(emil)
MERGE (michael)-[:KNOWS]-(emil)
MERGE (michael)-[:KNOWS]-(lju)
MERGE (michael)-[:KNOWS]-(praveena)
MERGE (emil)-[:FOLLOWS]->(joe)
MERGE (praveena)-[:FOLLOWS]->(joe)

此过程计算节点在指定跳数内的邻域。

以下返回 Praveena 在 2 跳内“`FOLLOWS`”的人数。

MATCH (p:Person {name: "Praveena"})
CALL apoc.neighbors.tohop.count(p, "FOLLOWS>", 2)
YIELD value
RETURN value

结果
value
2

如果我们还想知道哪些节点在我们的邻域中，我们也可以这样做。请参阅 apoc.neighbors.tohop。

更多关于 apoc.neighbors.tohop.count 的文档