|| apoc.path.subgraphNodes - APOC 核心文档 - Neo4j 文档

apoc.path.subgraphNodes

此过程不被认为在多线程环境下运行是安全的。因此，并行运行时不支持此过程。有关更多信息，请参阅Cypher 手册 → 并行运行时。
详情

语法

apoc.path.subgraphNodes(startNode, config) :: (node)

描述

返回从起始 NODE 沿着给定 RELATIONSHIP 类型到最大深度可达的子图中的 NODE 值。

输入参数

名称

类型

描述

startNode

ANY

算法开始的节点。startNode 可以是 STRING (elementId())、INTEGER (id())、NODE 或 LIST<STRING | INTEGER | NODE> 类型。

config

MAP

{ minLevel = -1 :: INTEGER, maxLevel = -1 :: INTEGER, relationshipFilter :: STRING, labelFilter :: STRING, beginSequenceAtStart = true :: BOOLEAN, uniqueness = ""RELATIONSHIP_PATH"" :: STRING, bfs = true :: BOOLEAN, filterStartNode = false :: BOOLEAN, limit = -1 :: INTEGER, optional = false :: BOOLEAN, endNodes :: LIST<NODES>, terminatorNodes:: LIST<NODES>, allowlistNodes:: LIST<NODES>, denylistNodes:: LIST<NODES> }

返回参数

名称

类型

描述

node

NODE

返回子图中的节点。

配置参数

该过程支持以下配置参数

配置参数
名称 类型 默认值 描述

minLevel

INTEGER

-1

遍历的最小跳数。如果指定，必须是 0 或 1

maxLevel

INTEGER

-1

遍历的最大跳数

relationshipFilter

STRING

null

要遍历的关系类型和方向。

请参阅关系过滤器。

labelFilter

STRING

null

要遍历的节点标签。

请参阅标签过滤器。

beginSequenceAtStart

BOOLEAN

true

开始匹配节点标签和/或关系类型（在 relationshipFilter、labelFilter 或 sequences 中定义）的序列，距离起始节点一个节点远。

bfs

BOOLEAN

true

遍历时使用广度优先搜索。如果设置为 false，则使用深度优先搜索

filterStartNode

BOOLEAN

false

labelFilter 和 sequence 是否应用于扩展的起始节点。

limit

INTEGER

-1

限制返回的路径数量。当使用 bfs:true 时，这会返回到终止或结束节点过滤器中包含标签的最近 n 个节点的路径，其中 n 是给定的限制。如果设置为 true，则每当扩展通常由于没有结果而消除行时，会产生 null 值。

endNodes

LIST<NODE>

null

只有这些节点可以结束返回的路径，并且扩展会尽可能地继续超过这些节点。

terminatorNodes

LIST<NODE>

null

只有这些节点可以结束返回的路径，并且扩展不会继续超过这些节点。

allowlistNodes

LIST<NODE>

null

只有这些节点允许在扩展中（如果存在，endNodes 和 terminatorNodes 也将允许）。

denylistNodes

LIST<NODE>

null

返回的路径中不包括这些节点。

whitelistNodes (已弃用)

LIST<NODE>

null

请参阅 allowlistNodes。

blacklistNodes (已弃用)

LIST<NODE>

null

请参阅 denylistNodes。

它还有以下固定参数

配置参数
名称 类型 默认值 描述

uniqueness

STRING

NODE_GLOBAL

遍历中扩展关系时使用的策略。NODE_GLOBAL 意味着一个节点不能被遍历多次。这是旧版遍历框架所做的。

关系过滤器

关系过滤器的语法描述如下

语法：[<]RELATIONSHIP_TYPE1[>]|[<]RELATIONSHIP_TYPE2[>]|…​

输入 类型 方向

LIKES>

LIKES

出站

<FOLLOWS

FOLLOWS

入站

KNOWS

KNOWS

双向

>

任何类型

出站

<

任何类型

入站

标签过滤器

标签过滤器的语法描述如下

语法：[+-/>]LABEL1|LABEL2|*|…​

符号 过滤器类型 输入示例 描述

-

拒绝列表

-Foe

路径中的任何节点都不能包含拒绝列表中的标签。

+

允许列表

+Friend

路径中的所有节点都必须包含允许列表中的标签（终止节点和结束节点除外，如果使用这些过滤器）。如果没有允许列表操作符，则允许所有标签。

/

终止

/Friend

只返回到具有给定标签的节点的路径，并停止进一步扩展。终止节点不必遵守允许列表。终止过滤优先于结束节点过滤。

>

结束节点

>Friend

只返回到具有给定标签的节点的路径，但继续扩展以匹配其后的结束节点。结束节点不必遵守允许列表才能返回，但只有当节点具有允许列表中的标签时，才允许对其进行扩展。

:

复合标签

Foe:Friend

这返回标签的合取，例如 /Foo:Bar 表示终止节点必须同时匹配 Foo 和 Bar。要在标签中包含没有特殊含义的 :，请使用 \ 进行转义，例如 Foo\:Bar 是标签 Foo:Bar。

标签过滤器运算符优先级和行为

允许同时使用多个标签过滤器运算符。请看以下示例

labelFilter:'+Person|Movie|-SciFi|>Western|/Romance'

通过这个标签过滤器，我们可以看到

  • :Person 和 :Movie 标签在允许列表中

  • :SciFi 在拒绝列表中

  • :Western 是一个结束节点标签

  • :Romance 是一个终止标签。

运算符评估的优先级不取决于它们在 labelFilter 中的位置，而是固定的

拒绝列表过滤器 -、终止过滤器 /、结束节点过滤器 >、允许列表过滤器 +。

这意味着

  • 返回路径的节点中绝不会出现拒绝列表中的标签 -，即使该标签（或具有拒绝列表标签的另一个节点的标签）包含在其他过滤器列表中。

  • 如果使用终止过滤器 / 或结束节点过滤器 >，则只返回到具有这些标签的节点的路径作为结果。这些结束节点不受允许列表过滤器的限制。

  • 如果节点是终止节点 /，则不会发生超出该节点的进一步扩展。

  • 允许列表仅适用于直到但不包括终止或结束节点过滤器中的结束节点。如果 labelFilter 中不存在结束节点或终止节点操作符，则允许列表适用于路径的所有节点。

  • 如果 labelFilter 中不存在允许列表操作符，则视为允许所有标签。

输出参数

名称 类型

node

NODE

使用示例

本节中的示例基于以下示例图

MERGE (mark:Person:DevRel {name: "Mark"})
MERGE (lju:Person:DevRel {name: "Lju"})
MERGE (praveena:Person:Engineering {name: "Praveena"})
MERGE (zhen:Person:Engineering {name: "Zhen"})
MERGE (martin:Person:Engineering {name: "Martin"})
MERGE (joe:Person:Field {name: "Joe"})
MERGE (stefan:Person:Field {name: "Stefan"})
MERGE (alicia:Person:Product {name: "Alicia"})
MERGE (jake:Person:Product {name: "Jake"})
MERGE (john:Person:Product {name: "John"})
MERGE (jonny:Person:Sales {name: "Jonny"})
MERGE (anthony:Person:Sales {name: "Anthony"})
MERGE (rik:Person:Sales {name: "Rik"})

MERGE (zhen)-[:KNOWS]-(stefan)
MERGE (zhen)-[:KNOWS]-(lju)
MERGE (zhen)-[:KNOWS]-(praveena)
MERGE (zhen)-[:KNOWS]-(martin)
MERGE (mark)-[:KNOWS]-(jake)
MERGE (alicia)-[:KNOWS]-(jake)
MERGE (jonny)-[:KNOWS]-(anthony)
MERGE (john)-[:KNOWS]-(rik)

MERGE (alicia)-[:FOLLOWS]->(joe)
MERGE (joe)-[:FOLLOWS]->(mark)
MERGE (joe)-[:FOLLOWS]->(praveena)
MERGE (joe)-[:FOLLOWS]->(zhen)
MERGE (mark)-[:FOLLOWS]->(stefan)
MERGE (stefan)-[:FOLLOWS]->(joe)
MERGE (praveena)-[:FOLLOWS]->(joe)
MERGE (lju)-[:FOLLOWS]->(jake)
MERGE (alicia)-[:FOLLOWS]->(jonny)
MERGE (zhen)-[:FOLLOWS]->(john)
MERGE (anthony)-[:FOLLOWS]->(joe)

下面的 Neo4j 浏览器可视化显示了示例图

apoc.path.expandConfig
图 1. 示例图

KNOWS 关系类型被认为是双向的，即如果 Zhen 认识 Stefan，我们可以推断 Stefan 认识 Zhen。在使用 KNOWS 关系时，我们将忽略方向。

FOLLOWS 关系有方向，因此在使用时我们将指定方向。

关系类型和节点标签过滤器

我们从 Praveena 节点开始扩展路径。我们只想考虑 KNOWS 关系类型，因此我们将其指定为 relationshipFilter 参数。

以下返回距离 Praveena 1 到 2 跳通过 KNOWS 关系可达的人员
MATCH (p:Person {name: "Praveena"})
CALL apoc.path.subgraphNodes(p, {
	relationshipFilter: "KNOWS",
    minLevel: 1,
    maxLevel: 2
})
YIELD node
RETURN node;
结果
node

(:Person:Engineering {name: "Zhen"})

(:Person:Engineering {name: "Martin"})

(:Person:DevRel {name: "Lju"})

(:Person:Field {name: "Stefan"})

有 4 个人可以从 Praveena 接触到。

我们还可以提供节点标签过滤器来限制返回的节点。如果只想返回所有节点都具有 Engineering 标签的路径，我们将为 labelFilter 参数提供值 +Engineering。

以下返回距离 Praveena 1 到 2 跳通过 KNOWS 关系可达的 Engineering 人员
MATCH (p:Person {name: "Praveena"})
CALL apoc.path.subgraphNodes(p, {
	relationshipFilter: "KNOWS",
	labelFilter: "+Engineering",
    minLevel: 1,
    maxLevel: 2
})
YIELD node
RETURN node;
结果
node

(:Person:Engineering {name: "Zhen"})

(:Person:Engineering {name: "Martin"})

我们失去了 Lju 和 Stefan，因为这些节点没有 Engineering 标签。

我们可以指定多种关系类型。以下查询从 Alicia 节点开始，然后扩展 FOLLOWS 和 KNOWS 关系

以下返回距离 Alicia 1 到 3 跳通过 FOLLOWS 或 KNOWS 关系可达的人员
MATCH (p:Person {name: "Alicia"})
CALL apoc.path.subgraphNodes(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3
})
YIELD node
RETURN node;
结果
node

(:Person:Sales {name: "Jonny"})

(:Person:Field {name: "Joe"})

(:Person:Product {name: "Jake"})

(:Person:Sales {name: "Anthony"})

(:Person:Engineering {name: "Praveena"})

(:Person:DevRel {name: "Mark"})

(:Person:Engineering {name: "Zhen"})

(:Person:Field {name: "Stefan"})

(:Person:Product {name: "John"})

(:Person:Engineering {name: "Martin"})

(:Person:DevRel {name: "Lju"})

此列表包含了我们图中的所有人，只差一个，这意味着 Alicia 的连接非常广泛。

我们还可以使用标签过滤器指定遍历终止条件。如果希望遍历在遇到包含 Engineering 标签的节点时立即终止，可以使用 /Engineering 节点过滤器。

以下返回距离 Alicia 1 到 3 跳通过 FOLLOWS 或 KNOWS 关系可达的人员，一旦到达带有 Engineering 标签的节点即终止
MATCH (p:Person {name: "Alicia"})
CALL apoc.path.subgraphNodes(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    labelFilter: "/Engineering",
    minLevel: 1,
    maxLevel: 3
})
YIELD node
RETURN node;
结果
node

(:Person:Engineering {name: "Zhen"})

(:Person:Engineering {name: "Praveena"})

现在我们只剩下 2 个人——Zhen 和 Praveena。但此查询并未捕获所有从 Alicia 开始并以 Engineering 标签节点结束的路径。我们可以使用 >Engineering 节点过滤器来定义一个遍历，该遍历

  • 只返回具有 Engineering 标签的节点

  • 在此之后继续扩展到结束节点，寻找更多具有 Engineering 标签的节点

以下返回距离 Alicia 1 到 3 跳通过 FOLLOWS 或 KNOWS 关系可达的 Engineering 人员
MATCH (p:Person {name: "Alicia"})
CALL apoc.path.subgraphNodes(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    labelFilter: ">Engineering",
    minLevel: 1,
    maxLevel: 3
})
YIELD node
RETURN node;
结果
node

(:Person:Engineering {name: "Zhen"})

(:Person:Engineering {name: "Praveena"})

(:Person:Engineering {name: "Martin"})

我们的查询现在也返回了 Martin，他一定是通过 Zhen 或 Praveena 接触到的。

终止节点和结束节点

除了为遍历指定终止标签和结束标签外，我们还可以指定终止节点和结束节点。对于此过程，这些参数的行为方式相同——该过程将确定作为终止节点或结束节点提供的任何节点是否可以从起始节点到达。

让我们在之前查询的基础上构建，该查询找到了 Alicia KNOWS 或 FOLLOWS 的人。我们想知道是否有办法从 Alicia 到 Joe，我们可以通过将 Joe 节点传递给 terminatorNodes 参数来做到这一点。

以下返回从 Alicia 1 到 3 跳通过 FOLLOWS 或 KNOWS 关系可达的终止节点
MATCH (p:Person {name: "Alicia"})
MATCH (joe:Person {name: "Joe"})
CALL apoc.path.subgraphNodes(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3,
    terminatorNodes: [joe]
})
YIELD node
RETURN node;
结果
node

(:Person:Field {name: "Joe"})

我们确实有一条从 Alicia 到 Joe 的路径。

我们从前面的一个例子中知道，Alicia 实际上可以使用 KNOWS 或 FOLLOWS 关系到达图中的所有其他节点。但是，如果我们只想通过 KNOWS 关系确定 Mark、Joe、Zhen 和 Praveena 是否可达呢？

以下返回从 Alicia 1 到 3 跳通过 KNOWS 关系可达的结束节点
MATCH (p:Person {name: "Alicia"})
MATCH (end:Person)
WHERE end.name IN ["Mark", "Joe", "Zhen", "Praveena"]
WITH p, collect(end) AS endNodes
CALL apoc.path.subgraphNodes(p, {
    relationshipFilter: "KNOWS",
    minLevel: 1,
    maxLevel: 3,
    endNodes: endNodes
})
YIELD node
RETURN node;
结果
node

(:Person:DevRel {name: "Mark"})

只有 Mark 可以到达！

允许列表节点和拒绝列表节点

也可以指定允许列表和拒绝列表节点。

让我们在之前查询的基础上构建，该查询找到了 Alicia KNOWS 或 FOLLOWS 的人。我们想找到只能包含 Jonny、Mark 或 Zhen 的路径可达的节点。我们可以通过将这些节点传递给 allowlistNodes 参数来做到这一点。

以下返回从 Alicia 1 到 3 跳通过 FOLLOWS 或 KNOWS 关系可达的节点，其中到达这些节点的路径只能包含 Mark、Jonny 或 Zhen
MATCH (p:Person {name: "Alicia"})
MATCH (allowlist:Person)
WHERE allowlist.name IN ["Jonny", "Mark", "Zhen"]
WITH p, collect(allowlist) AS allowlistNodes
CALL apoc.path.subgraphNodes(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3,
    allowlistNodes: allowlistNodes
})
YIELD node
RETURN node;
结果
node

(:Person:Sales {name: "Jonny"})

只有 Jonny 可以到达。因此我们可以推断，Mark 和 Zhen 只能通过不在允许列表中的其他节点才能到达。

拒绝列表用于从通向可达节点的路径中排除节点。如果我们想返回不经过 Joe 即可到达的节点，可以通过将 Joe 节点传递给 denylistNodes 参数来做到这一点。

以下返回从 Alicia 1 到 3 跳通过 FOLLOWS 或 KNOWS 关系可达的节点，其中到达这些节点的路径不经过 Joe
MATCH (p:Person {name: "Alicia"})
MATCH (joe:Person {name: "Joe"})
CALL apoc.path.subgraphNodes(p, {
    relationshipFilter: "FOLLOWS>|KNOWS",
    minLevel: 1,
    maxLevel: 3,
    denylistNodes: [joe]
})
YIELD node
RETURN node;
结果
node

(:Person:Sales {name: "Jonny"})

(:Person:Product {name: "Jake"})

(:Person:Sales {name: "Anthony"})

(:Person:DevRel {name: "Mark"})

(:Person:Field {name: "Stefan"})

只有 5 个节点在不经过 Joe 节点的情况下可达。如果我们回顾前面的一个例子，当我们没有指定拒绝列表时，有 11 个节点可达。这表明 Joe 在这个图中是一个重要的连接器。

关系类型序列

关系类型序列可以通过逗号分隔传递给 relationshipFilter 的值来指定。

例如，如果我们要从 Joe 节点开始，遍历一个方向为出站的 FOLLOWS 关系和任意方向的 KNOWS 关系序列，我们可以指定关系过滤器 FOLLOWS>,KNOWS。

以下返回从 Joe 交替沿着 FOLLOWS 和 KNOWS 关系类型可达的节点
MATCH (p:Person {name: "Joe"})
CALL apoc.path.subgraphNodes(p, {
	relationshipFilter: "FOLLOWS>,KNOWS",
	beginSequenceAtStart: true,
	minLevel: 1,
	maxLevel: 4
})
YIELD node
RETURN node;
结果
node

(:Person:Engineering {name: "Praveena"})

(:Person:DevRel {name: "Mark"})

(:Person:Engineering {name: "Zhen"})

(:Person:Product {name: "Jake"})

(:Person:Engineering {name: "Martin"})

(:Person:DevRel {name: "Lju"})

(:Person:Field {name: "Stefan"})

更多 apoc.path.subgraphNodes 文档

© . This site is unofficial and not affiliated with Neo4j, Inc.