|| apoc.node.degree.out - APOC 核心文档 - Neo4j 文档

apoc.node.degree.out

详情
语法	`apoc.node.degree.out(node [, relTypes ])`
描述	返回给定`NODE`中出站`RELATIONSHIP`值的总数。
参数	名称	类型	描述
	`node`	`NODE`	要计算出站关系总数的节点。
	`relTypes`	`STRING`	限制计数的关系类型。默认值为空字符串：``。
返回值	`INTEGER`

使用示例

本节示例基于以下样本图

MERGE (michael:Person {name: "Michael"})
WITH michael
CALL {
    WITH michael
    UNWIND range(0, 100) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:KNOWS]-(p)
    RETURN count(*) AS friends
}

CALL {
    WITH michael
    UNWIND range(0, 50) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:FOLLOWS]-(p)
    RETURN count(*) AS follows
}

RETURN friends, follows;

结果
朋友	关注
101	51

apoc.node.degree.out

MATCH (p:Person {name: "Person1"})
RETURN apoc.node.degree.out(p) AS output

使用Cypher的COUNT子查询和模式匹配

MATCH (p:Person {name: "Person1"})
RETURN COUNT { (p)-->() } AS output

结果
输出
0

apoc.node.degree.out

MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree.out(p) AS output

使用Cypher的COUNT子查询和模式匹配

MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)-->() } AS output

结果
输出
152

apoc.node.degree.out

MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree.out(p, "KNOWS") AS output

使用Cypher的COUNT子查询和模式匹配

MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)-[:KNOWS]->() } AS output

结果
输出
101