|| apoc.neighbors.byhop - APOC 核心文档 - Neo4j 文档

apoc.neighbors.byhop

详情
语法	`apoc.neighbors.byhop(node [, relTypes, distance ]) :: (nodes)`
描述	返回在指定距离内通过给定 `RELATIONSHIP` 类型连接的所有 `NODE` 值。返回 `LIST<NODE>` 值，其中每个 `NODE` 值 `PATH` 代表 `LIST<NODE>` 值的一行。
输入参数	名称	类型	描述
	`node`	`NODE`	算法的起始节点。
	`relTypes`	`STRING`	要遵循的关系类型列表。关系类型使用 APOC 的关系方向模式语法表示； `[<]RELATIONSHIP_TYPE1[>]\|[<]RELATIONSHIP_TYPE2[>]\|…`。默认值为: ``。
	`distance`	`INTEGER`	最大跳数。默认值为: `1`。
返回参数	名称	类型	描述
返回参数	`nodes`	`LIST<NODE>`	在不同跳数距离处的相邻节点列表。

使用示例

本节中的示例基于以下示例图

MERGE (mark:Person {name: "Mark"})
MERGE (praveena:Person {name: "Praveena"})
MERGE (joe:Person {name: "Joe"})
MERGE (lju:Person {name: "Lju"})
MERGE (michael:Person {name: "Michael"})
MERGE (emil:Person {name: "Emil"})
MERGE (ryan:Person {name: "Ryan"})

MERGE (ryan)-[:FOLLOWS]->(joe)
MERGE (joe)-[:FOLLOWS]->(mark)
MERGE (mark)-[:FOLLOWS]->(emil)
MERGE (michael)-[:KNOWS]-(emil)
MERGE (michael)-[:KNOWS]-(lju)
MERGE (michael)-[:KNOWS]-(praveena)
MERGE (emil)-[:FOLLOWS]->(joe)
MERGE (praveena)-[:FOLLOWS]->(joe)

apoc.neighbors.byhop 过程计算节点在多个跳数下的邻域。

以下返回 Emil 通过最多 2 跳“KNOWS”的人

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.byhop(p, "KNOWS", 2)
YIELD nodes
RETURN nodes

结果
nodes
[(:Person {name: "Michael"})]
[(:Person {name: "Praveena"}), (:Person {name: "Lju"})]

从这些结果中我们可以看到，在级别 1，Emil 认识 Michael，在级别 2，Emil 认识 Lju 和 Praveena。以下图模式描述了 Emil 如何认识不同的人

级别 1

(emil)-[:KNOWS]-(michael)

级别 2

(emil)-[:KNOWS]-(michael)-[:KNOWS]-(lju)
(emil)-[:KNOWS]-(michael)-[:KNOWS]-(praveena)

在搜索邻域时，我们还可以使用多种关系类型。

假设除了找到 Emil 认识的人之外，我们还想找到关注他的人。我们可以通过使用 < 来表示传入关系，或使用 > 来表示传出关系，从而为关系类型指定方向。因此，要找到关注 Emil 的人，我们将使用 <FOLLOWS。

以下返回 Emil 认识的人以及与他有 FOLLOWS 关系的人，最多 3 跳

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.byhop(p, "KNOWS|<FOLLOWS", 3)
YIELD nodes
RETURN nodes

结果
nodes
[(:Person {name: "Mark"}), (:Person {name: "Michael"})]
[(:Person {name: "Praveena"}), (:Person {name: "Joe"}), (:Person {name: "Lju"})]
[(:Person {name: "Ryan"})]

这次我们得到了更多的结果。Mark 位于 Emil 的 1 级邻域，Joe 位于 Emil 的 2 级邻域，Ryan 位于 Emil 的 3 级邻域。

以下图模式描述了 Emil 如何认识不同的人

级别 1

(emil)-[:KNOWS]-(michael)
(mark)-[:FOLLOWS]→(emil)

级别 2

(emil)-[:KNOWS]-(michael)-[:KNOWS]-(lju)
(emil)-[:KNOWS]-(michael)-[:KNOWS]-(praveena)
(joe)-[:FOLLOWS]→(mark)-[:FOLLOWS]→(emil)

级别 3

(ryan)-[:FOLLOWS]→(joe)-[:FOLLOWS]→(mark)-[:FOLLOWS]→(emil)

并且，与 apoc.neighbors.athop 过程一样，我们也可以只返回每个跳的邻域大小。

以下返回 Emil 认识的人数以及与他有 FOLLOWS 关系的人数，最多 3 跳

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.byhop.count(p, "KNOWS|<FOLLOWS", 3)
YIELD value
RETURN value

结果
值
[2, 3, 1]

正如预期，我们在级别 1 有 2 个，级别 2 有 3 个，级别 3 有 1 个。

我们甚至可以将该数字列表转换为一个映射，其中键是跳数，值是邻域大小。以下查询展示了如何使用 apoc.map.fromLists 函数来实现这一点

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.byhop.count(p, "KNOWS|<FOLLOWS", 3)
YIELD value
RETURN apoc.map.fromLists(
         [value in range(1, size(value)) | toString(value)],
         value) AS value

结果
值
{`1`: 2, `2`: 3, `3`: 1}

如果我们不关心邻域中有哪些节点，而只想要一个计数，我们也可以这样做。请参阅 apoc.neighbors.byhop.count。

apoc.neighbors.byhop 的更多文档