|| apoc.create.relationship - APOC 核心文档 - Neo4j 文档

apoc.create.relationship

详情
语法	`apoc.create.relationship(from, relType, props, to) :: (rel)`
描述	创建具有给定动态关系类型的 `RELATIONSHIP`。
输入参数	名称	类型	描述
	`from`	`NODE`	出站关系将从中开始的节点。
	`relType`	`STRING`	要分配给新关系的类型。
	`props`	`MAP`	要分配给新关系的属性。
	`to`	`NODE`	入站关系将连接到的节点。
返回参数	名称	类型	描述
返回参数	`rel`	`RELATIONSHIP`	创建的关系。

使用 Cypher 创建具有动态类型的关系

在 Cypher 中可以动态引用关系类型，无需使用 APOC。

动态创建类型的 Cypher 语法

CREATE ()-[r:$(type)]->()

动态计算的类型必须解析为 STRING 或 LIST<STRING>。更多信息请参阅《Cypher 手册》→ 使用动态节点标签和关系类型创建节点和关系。

使用示例

本节示例基于以下图

CREATE (p:Person {name: "Tom Hanks"})
CREATE (m:Movie {title:"You've Got Mail"});

以下示例演示了如何使用 APOC 和 Cypher 通过动态传递其类型和属性参数来创建关系

以下创建 relType 和 properties 参数

:param relType =>  ("ACTED_IN");
:param properties => ({roles: ["Joe Fox"]});

apoc.create.relationship

MATCH (p:Person {name: "Tom Hanks"})
MATCH (m:Movie {title:"You've Got Mail"})
CALL apoc.create.relationship(p, $relType, $properties, m)
YIELD rel
RETURN rel;

CREATE 子句

MATCH (p:Person {name: "Tom Hanks"})
MATCH (m:Movie {title:"You've Got Mail"})
CREATE (p)-[rel:$($relType) $properties]->(m)
RETURN rel;

结果
rel
[:ACTED_IN {roles: ["Joe Fox"]}]

apoc.create.relationship 的更多文档