|| apoc.map.values - APOC 核心文档 - Neo4j 文档

apoc.map.values

详情
语法	`apoc.map.values(map [, keys, addNullsForMissing ])`
描述	返回一个由给定键指定的 `LIST<ANY>`（如果给定键缺失，则返回 null 值）。
参数	名称	类型	描述
	`map`	`MAP`	从中提取值的映射。
	`keys`	`LIST<STRING>`	要从给定映射中提取的键列表。默认值是：`[]`。
	`addNullsForMissing`	`BOOLEAN`	是否将缺失值作为 null 值返回。默认值是：`false`。
返回	`LIST<ANY>`

用法示例

以下示例返回键 name 和 country 的值列表，以及缺失键 missingKey 的 null 值，同时使用 APOC 和 Cypher

apoc.map.values

WITH {name:"Cristiano Ronaldo",country:"Portugal",dob:date("1985-02-05")} AS map
RETURN apoc.map.values(map, ["name", "country", "missingKey"], true) AS output

使用 Cypher 的动态映射访问

WITH {name:"Cristiano Ronaldo",country:"Portugal",dob:date("1985-02-05")} AS map
RETURN [map["name"], map["country"], map["missingKey"]] AS output

使用 Cypher 的 COLLECT 子查询

WITH {name:"Cristiano Ronaldo",country:"Portugal",dob:date("1985-02-05")} AS map
RETURN COLLECT {
    UNWIND ["name", "country", "missingKey"] AS key
    RETURN map[key]
} AS output

结果
输出
["Cristiano Ronaldo","Portugal",null]

以下示例返回键 name 和 country 的值列表，但对于缺失键 missingKey 不返回任何内容，同时使用 APOC 和 Cypher

apoc.map.values

WITH {name:"Cristiano Ronaldo",country:"Portugal",dob:date("1985-02-05")} AS map
RETURN apoc.map.values(map, ["name", "country", "missingKey"], false) AS output

使用 Cypher 的动态映射访问和 collect()

WITH {name:"Cristiano Ronaldo",country:"Portugal",dob:date("1985-02-05")} AS map
UNWIND ["name", "country", "missingKey"] AS key
RETURN collect(map[key])

结果
输出
["Cristiano Ronaldo","Portugal"]