|| apoc.meta.nodes.count - APOC 核心文档 - Neo4j 文档

apoc.meta.nodes.count

详情
语法	`apoc.meta.nodes.count([ nodes, config ])`
描述	返回给定标签的 `NODE` 值在 `LIST<STRING>` 中的总和。
参数	名称	类型	描述
	`nodes`	`LIST<STRING>`	一个节点标签列表。默认值为：`[]`。
	`config`	`MAP`	一个关系、节点或映射，用于获取属性类型。{ includeRels = [] :: LIST<STRING> } 默认值为：`{}`。
返回	`INTEGER`

配置参数

此过程支持以下配置参数

配置参数
名称	类型	默认值	描述
includeRels	LIST<STRING>	[]	要包含的关系类型。默认是包含所有关系类型。在关系类型名称后添加后缀 `>` 或 `<` 以指示出站或入站关系。

已弃用参数
名称	类型	默认值	描述
rels	LIST<STRING>	[]	已弃用，请使用 `includeRels`

此函数将根据节点匹配给定标签的次数进行计数。要获得更准确的结果，请使用 Cypher 的标签表达式。

使用示例

本节中的示例基于以下示例图

CREATE (n:MyCountLabel {id: 1}), (:MyCountLabel {id: 2}), (m:ThirdLabel {id: 3})
CREATE (n)-[:MY_COUNT_REL]->(m), (n)-[:ANOTHER_MY_COUNT_REL]->(m), (n)<-[:ANOTHER_MY_COUNT_REL]-(m)

我们可以使用 APOC 和 Cypher 返回所有带有标签 MyCountLabel 或 ThirdLabel 的节点

apoc.meta.nodes.count

RETURN apoc.meta.nodes.count(['MyCountLabel', 'ThirdLabel']) AS count

使用 Cypher 的 count()

MATCH (n:MyCountLabel|ThirdLabel)
RETURN count(n) AS count

结果
count
3

以下示例使用 APOC 和 Cypher 返回所有带有标签 MyCountLabel 和关系 MY_COUNT_REL 的节点

apoc.meta.nodes.count

RETURN apoc.meta.nodes.count(['MyCountLabel'], {includeRels: ['MY_COUNT_REL']}) AS count;

使用 Cypher 的 count()

MATCH (n:MyCountLabel)-[:MY_COUNT_REL]-()
RETURN count(n) AS count

结果
count
1

以下示例使用 APOC 和 Cypher 返回所有带有出站关系 MY_COUNT_REL 的节点

apoc.meta.nodes.count

RETURN apoc.meta.nodes.count(['MyCountLabel'], {includeRels: ['MY_COUNT_REL>']}) AS count;

使用 Cypher 的 count()

MATCH (n:MyCountLabel)-[:MY_COUNT_REL]->()
RETURN count(n) AS count

结果
count
1

以下示例使用 APOC 和 Cypher 返回所有带有入站关系 MY_COUNT_REL 的节点

apoc.meta.nodes.count

RETURN apoc.meta.nodes.count(['MyCountLabel'], {includeRels: ['MY_COUNT_REL<']}) AS count;

使用 Cypher 的 count()

MATCH (n:MyCountLabel)<-[:MY_COUNT_REL]-()
RETURN count(n) AS count

结果
count
0