|| apoc.export.csv.query - APOC 核心文档 - Neo4j 文档

apoc.export.csv.query

此过程不被认为是多线程安全运行的。因此，并行运行时不支持此过程。欲了解更多信息，请参阅 Cypher 手册 → 并行运行时。

详情
语法	`apoc.export.csv.query(query, file, config) :: (file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data)`
描述	将运行给定 Cypher 查询的结果导出到提供的 CSV 文件。
输入参数	名称	类型	描述
	`query`	`STRING`	用于收集导出数据的查询。
	`file`	`STRING`	数据将导出到的文件名称。
	`config`	`MAP`	`{ stream = false :: BOOLEAN, batchSize = 20000 :: INTEGER, bulkImport = false :: BOOLEAN, timeoutSeconds = 100 :: INTEGER, compression = 'None' :: STRING, charset = 'UTF_8' :: STRING, quotes = 'always' :: ['always', 'none', 'ifNeeded'], differentiateNulls = false :: BOOLEAN, sampling = false :: BOOLEAN, samplingConfig :: MAP }`
返回参数	名称	类型	描述
	`file`	`STRING`	数据导出到的文件名称。
	`source`	`STRING`	导出数据的摘要。
	`format`	`STRING`	文件导出的格式。
	`nodes`	`INTEGER`	导出的节点数量。
	`relationships`	`INTEGER`	导出的关系数量。
	`properties`	`INTEGER`	导出的属性数量。
	`time`	`INTEGER`	导出持续时间。
	`rows`	`INTEGER`	返回的行数。
	`batchSize`	`INTEGER`	导出运行的批次大小。
	`batches`	`INTEGER`	导出运行的批次数量。
	`done`	`BOOLEAN`	导出是否成功运行。
	`data`	`ANY`	导出返回的数据。

使用示例

本节中的示例基于以下示例图

CREATE (TheMatrix:Movie {title:'The Matrix', released:1999, tagline:'Welcome to the Real World'})
CREATE (Keanu:Person {name:'Keanu Reeves', born:1964})
CREATE (Carrie:Person {name:'Carrie-Anne Moss', born:1967})
CREATE (Laurence:Person {name:'Laurence Fishburne', born:1961})
CREATE (Hugo:Person {name:'Hugo Weaving', born:1960})
CREATE (LillyW:Person {name:'Lilly Wachowski', born:1967})
CREATE (LanaW:Person {name:'Lana Wachowski', born:1965})
CREATE (JoelS:Person {name:'Joel Silver', born:1952})
CREATE
(Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrix),
(Carrie)-[:ACTED_IN {roles:['Trinity']}]->(TheMatrix),
(Laurence)-[:ACTED_IN {roles:['Morpheus']}]->(TheMatrix),
(Hugo)-[:ACTED_IN {roles:['Agent Smith']}]->(TheMatrix),
(LillyW)-[:DIRECTED]->(TheMatrix),
(LanaW)-[:DIRECTED]->(TheMatrix),
(JoelS)-[:PRODUCED]->(TheMatrix);

下面的 Neo4j Browser 可视化显示了导入的图

apoc.export.csv.query 过程将 Cypher 查询结果导出到 CSV 文件或作为流输出。

以下查询将所有 `DIRECTED` 关系以及该关系两侧带有 `Person` 和 `Movie` 标签的节点导出到文件 `movies-directed.csv`

WITH "MATCH path = (person:Person)-[:DIRECTED]->(movie)
      RETURN person.name AS name, person.born AS born,
             movie.title AS title, movie.tagline AS tagline, movie.released AS released" AS query
CALL apoc.export.csv.query(query, "movies-directed.csv", {})
YIELD file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data
RETURN file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data;

结果
file	source	format	nodes	relationships	properties	time	rows	batchSize	batches	done	data
"movies-directed.csv"	"statement: cols(5)"	"csv"	0	0	10	3	2	20000	1	TRUE	NULL

`movies-directed.csv` 的内容如下所示

"name","born","role","title","tagline","released"
"Lilly Wachowski","1967","","The Matrix","Welcome to the Real World","1999"
"Lana Wachowski","1965","","The Matrix","Welcome to the Real World","1999"

以下查询返回所有 `DIRECTED` 关系以及该关系两侧带有 `Person` 和 `Movie` 标签的节点的流

WITH "MATCH path = (person:Person)-[:DIRECTED]->(movie)
      RETURN person.name AS name, person.born AS born,
             movie.title AS title, movie.tagline AS tagline, movie.released AS released" AS query
CALL apoc.export.csv.query(query, null, {stream: true})
YIELD file, nodes, relationships, properties, data
RETURN file, nodes, relationships, properties, data;

结果
file	nodes	relationships	properties	data
NULL	0	0	10	"\"name\",\"born\",\"title\",\"tagline\",\"released\" \"Lilly Wachowski\",\"1967\",\"The Matrix\",\"Welcome to the Real World\",\"1999\" \"Lana Wachowski\",\"1965\",\"The Matrix\",\"Welcome to the Real World\",\"1999\" "

apoc.export.csv.query 更多文档