|| apoc.node.relationship.types - APOC 核心文档 - Neo4j 文档

apoc.node.relationship.types

详情
语法	`apoc.node.relationship.types(node [, relTypes ])`
描述	返回给定 `NODE` 的不同 `RELATIONSHIP` 类型 `LIST<STRING>`。
参数	名称	类型	描述
	`node`	`NODE`	要返回连接关系类型的节点。
	`relTypes`	`STRING`	如果不为空，提供要返回的关系类型允许列表。关系类型使用 APOC 的关系方向模式语法表示；`[<]RELATIONSHIP_TYPE1[>]\|[<]RELATIONSHIP_TYPE2[>]\|…`。默认值为空字符串。
返回	`LIST<ANY>`

使用示例

本节示例基于以下示例图

MERGE (michael:Person {name: "Michael"})
WITH michael
CALL {
    WITH michael
    UNWIND range(0, 100) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:KNOWS]-(p)
    RETURN count(*) AS friends
}

CALL {
    WITH michael
    UNWIND range(0, 50) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:FOLLOWS]-(p)
    RETURN count(*) AS follows
}

RETURN friends, follows;

结果
friends	follows
101	51

apoc.node.relationship.types

MATCH (p1:Person {name: "Person30"})
RETURN apoc.node.relationship.types(p1) AS output;

使用 Cypher 的 COLLECT {} 和 type()

MATCH (p1:Person {name: "Person30"})
RETURN COLLECT {
    MATCH (p1)-[r]-()
    RETURN DISTINCT type(r)
} AS output

结果
输出
["KNOWS", "FOLLOWS"]

apoc.node.relationship.types

MATCH (p1:Person {name: "Person30"})
RETURN apoc.node.relationship.types(p1, "FOLLOWS") AS output;

使用 Cypher 的 COLLECT {} 和 type()

MATCH (p1:Person {name: "Person30"})
RETURN COLLECT {
    MATCH (p1)-[r:FOLLOWS]-()
    RETURN DISTINCT type(r)
} AS output

结果
输出
["FOLLOWS"]