apoc.refactor.rename.nodeProperty
过程Cypher 25 中已弃用

此过程已弃用。请改用 Cypher 的 SET 和 REMOVE 子句。

详细信息
语法	`apoc.refactor.rename.nodeProperty(oldName, newName [, nodes, config ]) :: (batches, total, timeTaken, committedOperations, failedOperations, failedBatches, retries, errorMessages, batch, operations, constraints, indexes)`
描述	将所有 `NODE`（节点）的指定属性从 `oldName` 重命名为 `newName`。如果提供了 `LIST<NODE>`，则重命名仅应用于该 `LIST<NODE>` 中的 `NODE` 值。
输入参数	名称	类型	描述
	`oldName`	`STRING`	要重命名的属性名。
	`newName`	`STRING`	属性的新名称。
	`节点`	`LIST<NODE>`	要应用新名称的节点。如果此列表为空，则所有具有旧属性名称的节点都将被重命名。默认值为：`[]`。
	`config`	`MAP`	{ batchSize = 100000 :: INTEGER, concurrency :: INTEGER, retries = 0 :: INTEGER, parallel = true :: BOOLEAN, batchMode = "BATCH" :: STRING } 默认值为：`{}.
返回参数	名称	类型	描述
	`batches`	`INTEGER（整数）`	操作运行的批次数。
	`总计`	`INTEGER（整数）`	执行重命名的总数。
	`耗时`	`INTEGER（整数）`	完成操作所花费的时间。
	`已提交的操作`	`INTEGER（整数）`	已提交操作的总数。
	`failedOperations`	`INTEGER（整数）`	失败操作的总数。
	`failedBatches`	`INTEGER（整数）`	失败批次的总数。
	`retries`	`INTEGER（整数）`	重试的总次数。
	`errorMessages`	`MAP`	收集的错误消息。
	`batch`	`MAP`	`{ total :: INTEGER, failed :: INTEGER, committed :: INTEGER, errors :: MAP }`
	`操作`	`MAP`	`{ total :: INTEGER, failed :: INTEGER, committed :: INTEGER, errors :: MAP }`
	`constraints`	`LIST<STRING>`	与给定标签或类型关联的约束。
	`indexes`	`LIST<STRING>`	与给定标签或类型关联的索引。

使用 Cypher 设置和删除属性

无需使用 APOC，即可在 Cypher 中动态引用属性。

用于从节点或关系中动态设置和删除属性的 Cypher 语法

SET n[key] = <expr>
REMOVE n[key]

动态计算的键必须解析为 STRING 值。有关更多信息，请参阅《Cypher 手册》→ 动态设置或更新属性和动态删除属性。

使用示例

本节中的示例基于以下示例图

CREATE (mark:DevRel {name: "Mark", city: "London"})
CREATE (jennifer:DevRel {name: "Jennifer", city: "St Louis"})
CREATE (michael:DevRel {name: "Michael", city: "Dresden"})
CREATE (jim:Engineer {name: "Jim", city: "London"})
CREATE (alistair:Engineer {name: "Alistair", city: "London"})

以下查询使用 APOC 和 Cypher 将所有具有 DevRel 标签的节点的 city 属性更改为 location

apoc.refactor.rename.nodeProperty

MATCH (person:DevRel)
WITH collect(person) AS people
CALL apoc.refactor.rename.nodeProperty("city", "location", people)
YIELD total
RETURN total

使用 Cypher

MATCH (person:DevRel)
SET person.location = person.city
REMOVE person.city
RETURN count(*) AS total

结果
总计
3

以下查询在完成此重构后返回图中的所有节点

MATCH (n)
RETURN (n)

结果
n
(:DevRel {name: "Jennifer", location: "St Louis"})
(:DevRel {name: "Michael", location: "Dresden"})
(:Engineer {city: "London", name: "Jim"})
(:DevRel {name: "Mark", location: "London"})
(:Engineer {city: "London", name: "Alistair"})

此过程并不会直接重命名属性；它会创建一个具有新名称的新属性，并将原始属性的值复制过去，然后删除原始属性。

关于 apoc.refactor.rename.nodeProperty 的更多文档

apoc.refactor.rename.nodeProperty过程Cypher 25 中已弃用

使用 Cypher 设置和删除属性

使用示例

apoc.refactor.rename.nodeProperty
过程Cypher 25 中已弃用