apoc.cypher.runFirstColumnSingle
函数

详细信息
语法	`apoc.cypher.runFirstColumnSingle(statement, params)`
描述	执行给定的语句及其参数，并返回第一列的第一个元素。
参数	名称	类型	描述
	`statement`	`STRING`	要执行的 Cypher 查询语句。
	`params`	`MAP`	给定 Cypher 查询所需的输入参数。
返回	`ANY`

此函数在多线程环境下运行不安全。因此，它不支持并行运行时（Parallel runtime）。更多信息，请参阅 Cypher 手册 → 并行运行时。

在 Cypher 中使用动态标签

在 Cypher 中，无需使用 APOC 即可动态引用节点标签和关系类型。

用于动态创建、匹配和合并标签与类型的 Cypher 语法

CREATE (n1:$(label))-[r:$(type)]->(n2:$(label))
MERGE (n1:$(label))-[r:$(type)]->(n2:$(label))
MATCH (n1:$(label))-[r:$(type)]->(n2:$(label))

动态计算出的类型必须求值为 STRING 或 LIST<STRING>。更多信息，请参阅 Cypher 手册 → CREATE、MERGE、MATCH。

用法示例

本节中的示例基于以下示例图

CREATE (Keanu:Person {name:'Keanu Reeves', born:1964})
CREATE (TomH:Person {name:'Tom Hanks', born:1956})
CREATE (TomT:Person {name:'Tom Tykwer', born:1965})

CREATE (TheMatrix:Movie {title:'The Matrix', released:1999, tagline:'Welcome to the Real World'})
CREATE (TheMatrixReloaded:Movie {title:'The Matrix Reloaded', released:2003, tagline:'Free your mind'})
CREATE (TheMatrixRevolutions:Movie {title:'The Matrix Revolutions', released:2003, tagline:'Everything that has a beginning has an end'})
CREATE (SomethingsGottaGive:Movie {title:"Something's Gotta Give", released:2003})
CREATE (TheDevilsAdvocate:Movie {title:"The Devil's Advocate", released:1997, tagline:'Evil has its winning ways'})

CREATE (YouveGotMail:Movie {title:"You've Got Mail", released:1998, tagline:'At odds in life... in love on-line.'})
CREATE (SleeplessInSeattle:Movie {title:'Sleepless in Seattle', released:1993, tagline:'What if someone you never met, someone you never saw, someone you never knew was the only someone for you?'})
CREATE (ThatThingYouDo:Movie {title:'That Thing You Do', released:1996, tagline:'In every life there comes a time when that thing you dream becomes that thing you do'})
CREATE (CloudAtlas:Movie {title:'Cloud Atlas', released:2012, tagline:'Everything is connected'})

CREATE (Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrix)
CREATE (Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrixReloaded)
CREATE (Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrixRevolutions)
CREATE (Keanu)-[:ACTED_IN {roles:['Julian Mercer']}]->(SomethingsGottaGive)
CREATE (Keanu)-[:ACTED_IN {roles:['Kevin Lomax']}]->(TheDevilsAdvocate)

CREATE (TomH)-[:ACTED_IN {roles:['Joe Fox']}]->(YouveGotMail)
CREATE (TomH)-[:ACTED_IN {roles:['Sam Baldwin']}]->(SleeplessInSeattle)
CREATE (TomH)-[:ACTED_IN {roles:['Mr. White']}]->(ThatThingYouDo)
CREATE (TomH)-[:ACTED_IN {roles:['Zachry', 'Dr. Henry Goose', 'Isaac Sachs', 'Dermot Hoggins']}]->(CloudAtlas)
CREATE (TomT)-[:DIRECTED]->(CloudAtlas);

此函数适用于执行包含动态节点标签或关系类型的 Cypher 语句，并返回单行单列的结果。当然，在不使用 APOC 的情况下也可以实现同样的功能（在可能的情况下，下面的示例将同时展示 Cypher 原生和 APOC 的替代方案）。

例如，我们可以通过运行以下查询来返回所有标签及其计数的对象

apoc.cypher.runFirstColumnSingle

CALL db.labels()
YIELD label
RETURN label,
       apoc.cypher.runFirstColumnSingle("MATCH (:" + label + ") RETURN count(*)", {}) AS count;

MATCH 子句

CALL db.labels()
YIELD label
MATCH (n:$(label))
RETURN label, count(n);

结果
标签 (label)	count
"Person"	3
"Movie"	9

我们还可以通过运行以下查询来返回所有关系类型的计数

apoc.cypher.runFirstColumnSingle

CALL db.relationshipTypes()
YIELD relationshipType
RETURN relationshipType,
       apoc.cypher.runFirstColumnSingle("MATCH ()-[:" + relationshipType + "]->() RETURN count(*)", {}) AS count;

MATCH 子句

CALL db.relationshipTypes()
YIELD relationshipType
MATCH ()-[r:$(relationshipType)]->()
RETURN relationshipType, count(r) AS count;

结果
关系类型 (relationshipType)	count
"ACTED_IN"	9
"DIRECTED"	1

apoc.cypher.runFirstColumnSingle函数

在 Cypher 中使用动态标签

用法示例

apoc.cypher.runFirstColumnSingle
函数