apoc.node.degree
函数在 Cypher 25 中已弃用

此函数已被弃用。如需对简单模式进行度数查找，请改用 Cypher 的 COUNT 子查询。例如：RETURN COUNT { (p)--() }
详细信息

语法

apoc.node.degree(node [, relTypes ])

描述

返回给定 NODE 的总度数。

参数

名称

类型

描述

节点

NODE

用于计算关系总数的节点。

关系类型

STRING

用于限制统计范围的关系类型。关系类型使用 APOC 的关系-方向-模式（rel-direction-pattern）语法表示：[<]RELATIONSHIP_TYPE1[>]|[<]RELATIONSHIP_TYPE2[>]|…​。默认值为：``。

返回

INTEGER（整数）

用法示例

本节中的示例基于以下示例图

MERGE (michael:Person {name: "Michael"})
WITH michael
CALL {
    WITH michael
    UNWIND range(0, 100) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:KNOWS]-(p)
    RETURN count(*) AS friends
}

CALL {
    WITH michael
    UNWIND range(0, 50) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:FOLLOWS]-(p)
    RETURN count(*) AS follows
}

RETURN friends, follows;
结果
friends follows

101

51
apoc.node.degree
MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree(p) AS output
使用 Cypher 的 count() 函数和模式匹配
MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)--() } AS output
结果
输出

152
apoc.node.degree
MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree(p, "FOLLOWS>") AS output
使用 Cypher 的 count() 函数和模式匹配
MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)-[:FOLLOWS]->() } AS output
结果
输出

51
apoc.node.degree
MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree(p, "<KNOWS") AS output
使用 Cypher 的 COUNT 子查询和模式匹配
MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)<-[:KNOWS]-() } AS output
结果
输出

0