apoc.neighbors.athop
过程

详细信息
语法	`apoc.neighbors.athop(node [, relTypes, distance ]) :: (node)`
描述	返回所有通过给定的 `RELATIONSHIP`（关系）类型在指定距离内连接的 `NODE`（节点）值。
输入参数	名称	类型	描述
	`节点`	`NODE`	算法的起始节点。
	`关系类型`	`STRING`	要追踪的关系类型列表。关系类型使用 APOC 的关系方向模式语法表示；`[<]RELATIONSHIP_TYPE1[>]\|[<]RELATIONSHIP_TYPE2[>]\|…`。默认值为：``。
	`距离`	`INTEGER（整数）`	要跨越的跳数。默认值为：`1`。
返回参数	名称	类型	描述
返回参数	`节点`	`NODE`	邻居节点。

使用示例

本节中的示例基于以下示例图

MERGE (mark:Person {name: "Mark"})
MERGE (praveena:Person {name: "Praveena"})
MERGE (joe:Person {name: "Joe"})
MERGE (lju:Person {name: "Lju"})
MERGE (michael:Person {name: "Michael"})
MERGE (emil:Person {name: "Emil"})
MERGE (ryan:Person {name: "Ryan"})

MERGE (ryan)-[:FOLLOWS]->(joe)
MERGE (joe)-[:FOLLOWS]->(mark)
MERGE (mark)-[:FOLLOWS]->(emil)
MERGE (michael)-[:KNOWS]-(emil)
MERGE (michael)-[:KNOWS]-(lju)
MERGE (michael)-[:KNOWS]-(praveena)
MERGE (emil)-[:FOLLOWS]->(joe)
MERGE (praveena)-[:FOLLOWS]->(joe)

此过程计算节点在特定跳数下的邻居。

以下查询返回 Emil 在 1 跳距离内 KNOWS（认识）的人

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.athop(p, "KNOWS", 1)
YIELD node
RETURN node

结果
节点
(:Person {name: "Michael"})

Emil 与 Michael 只有直接的 KNOWS 关系，因此 Michael 是该查询返回的唯一节点。

以下查询返回 Emil 在 2 跳距离内 KNOWS（认识）的人

MATCH (p:Person {name: "Emil"})
CALL apoc.neighbors.athop(p, "KNOWS", 2)
YIELD node
RETURN node

结果
节点
(:Person {name: "Praveena"})
(:Person {name: "Lju"})

Michael 也 KNOWS Praveena 和 Lju，由于 Emil 并不直接 KNOWS 这两人，所以他是在 2 跳的距离上 KNOWS 他们。

如果我们不关心邻域中具体是哪些节点，而只想知道数量，也可以实现。请参阅 apoc.neighbors.athop.count。

有关 apoc.neighbors.athop 的更多文档

apoc.neighbors.athop过程

使用示例

apoc.neighbors.athop
过程