apoc.node.relationship.exists
函数在 Cypher 25 中已弃用

此函数已弃用。请改用 Cypher 的 EXISTS 子查询。
详细信息

语法

apoc.node.relationship.exists(node [, relTypes ])

描述

根据给定的 NODE 是否具有连接的 RELATIONSHIP（或者给定的 NODE 是否具有指定类型和方向的连接 RELATIONSHIP）返回一个 BOOLEAN 值。

参数

名称

类型

描述

节点

NODE

要检查指定关系类型的节点。

关系类型

STRING

要在给定节点上检查的关系类型。关系类型使用 APOC 的 rel-direction-pattern 语法表示；[<]RELATIONSHIP_TYPE1[>]|[<]RELATIONSHIP_TYPE2[>]|…​。默认值为：``。

返回

布尔值 (BOOLEAN)
此函数在本地（on-premise）实例中受限。要使用它，必须解除限制。详情请参阅 安装 → 加载并解除限制。

使用示例

本节中的示例基于以下示例图

MERGE (michael:Person {name: "Michael"})
WITH michael
CALL {
    WITH michael
    UNWIND range(0, 100) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:KNOWS]-(p)
    RETURN count(*) AS friends
}

CALL {
    WITH michael
    UNWIND range(0, 50) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:FOLLOWS]-(p)
    RETURN count(*) AS follows
}

RETURN friends, follows;
结果
friends follows

101

51
apoc.node.relationship.exists
MATCH (p1:Person {name: "Michael"})
RETURN apoc.node.relationship.exists(p1) AS output;
使用 Cypher 的 EXISTS {}
MATCH (p1:Person {name: "Michael"})
RETURN EXISTS {
    (p1)--()
} AS output
结果
输出

true
apoc.node.relationship.exists
MATCH (p1:Person {name: "Person40"})
RETURN apoc.node.relationship.exists(p1, "FOLLOWS>") AS output;
使用 Cypher 的 EXISTS {}
MATCH (p1:Person {name: "Person40"})
RETURN EXISTS {
    (p1)-[:FOLLOWS]->()
} AS output
结果
输出

false
apoc.node.relationship.exists
MATCH (p1:Person {name: "Person40"})
RETURN apoc.node.relationship.exists(p1, "<FOLLOWS") AS output;
使用 Cypher 的 EXISTS {}
MATCH (p1:Person {name: "Person40"})
RETURN EXISTS {
    (p1)<-[:FOLLOWS]-()
} AS output
结果
输出

true