apoc.agg.graph
函数在 Cypher 25 中已弃用

此函数已弃用。请改用 Cypher 的 COLLECT 子查询。

详细信息
语法	`apoc.agg.graph(path)`
描述	返回所有不同的 `NODE`（节点）和 `RELATIONSHIP`（关系）值，并收集到一个以 `nodes` 和 `relationships` 为键的 `MAP`（映射）中。
参数	名称	类型	描述
	`path`	`ANY`	用于返回节点和关系的路径。
返回	`MAP`

用法示例

本节中的示例基于以下示例图

CREATE (Keanu:Person {name:'Keanu Reeves', born:1964})
CREATE (TomH:Person {name:'Tom Hanks', born:1956})

CREATE (TheDevilsAdvocate:Movie {title:"The Devil's Advocate", released:1997, tagline:'Evil has its winning ways'})
CREATE (TheMatrix:Movie {title:'The Matrix', released:1999, tagline:'Welcome to the Real World'})
CREATE (TheMatrixReloaded:Movie {title:'The Matrix Reloaded', released:2003, tagline:'Free your mind'})

CREATE (SleeplessInSeattle:Movie {title:'Sleepless in Seattle', released:1993, tagline:'What if someone you never met, someone you never saw, someone you never knew was the only someone for you?'})
CREATE (ThatThingYouDo:Movie {title:'That Thing You Do', released:1996, tagline:'In every life there comes a time when that thing you dream becomes that thing you do'})
CREATE (YouveGotMail:Movie {title:"You've Got Mail", released:1998, tagline:'At odds in life... in love on-line.'})

CREATE (Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrix)
CREATE (Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrixReloaded)
CREATE (Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheDevilsAdvocate)

CREATE (TomH)-[:ACTED_IN {roles:['Joe Fox']}]->(YouveGotMail)
CREATE (TomH)-[:ACTED_IN {roles:['Sam Baldwin']}]->(SleeplessInSeattle)
CREATE (TomH)-[:ACTED_IN {roles:['Mr. White']}]->(ThatThingYouDo);

以下示例展示了如何同时使用 APOC 和 Cypher 提取基努·里维斯 (Keanu Reeves) 和汤姆·汉克斯 (Tom Hanks) 在 1998 年之前出演的电影的子图。

apoc.agg.graph

MATCH path = (person:Person)-[:ACTED_IN]->(movie)
WHERE movie.released < 1998
WITH apoc.agg.graph(path) AS g
RETURN g.nodes AS nodes, g.relationships AS relationships

Cypher 的 COLLECT {}

MATCH path = (person:Person)-[:ACTED_IN]->(movie)
WHERE movie.released < 1998
RETURN
  COLLECT {
    UNWIND nodes(path) AS n
    RETURN DISTINCT n
  } AS nodes,
  COLLECT {
    UNWIND relationships(path) AS r
    RETURN DISTINCT r
  } AS relationships

结果
节点	relationships
[(:Person {name: "Keanu Reeves", born: 1964}), (:Person {name: "Tom Hanks", born: 1956}), (:Movie {tagline: "Evil has its winning ways", title: "The Devil’s Advocate", released: 1997}), (:Movie {tagline: "What if someone you never met, someone you never saw, someone you never knew was the only someone for you?", title: "Sleepless in Seattle", released: 1993}), (:Movie {tagline: "In every life there comes a time when that thing you dream becomes that thing you do", title: "That Thing You Do", released: 1996})]	[[:ACTED_IN {roles: ["Neo"]}], [:ACTED_IN {roles: ["Sam Baldwin"]}], [:ACTED_IN {roles: ["Mr. White"]}]]