apoc.export.csv.data
过程

此过程不建议在多线程中运行，因此并行运行时（Parallel runtime）不支持该过程。有关更多信息，请参阅 Cypher 手册 → 并行运行时。

详细信息
语法	`apoc.export.csv.data(nodes, rels, file, config) :: (file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data)`
描述	将给定的 `NODE`（节点）和 `RELATIONSHIP`（关系）值导出到指定的 CSV 文件中。
输入参数	名称	类型	描述
	`节点`	`LIST<NODE>`	要导出的节点列表。
	`rels`	`LIST<RELATIONSHIP>`	要导出的关系列表。
	`file`	`STRING`	要导出数据的文件名。
	`config`	`MAP`	`{ stream = false :: BOOLEAN, batchSize = 20000 :: INTEGER, bulkImport = false :: BOOLEAN, timeoutSeconds = 100 :: INTEGER, compression = 'None' :: STRING, charset = 'UTF_8' :: STRING, quotes = 'always' :: ['always', 'none', 'ifNeeded'], differentiateNulls = false :: BOOLEAN, sampling = false :: BOOLEAN, samplingConfig :: MAP }`
返回参数	名称	类型	描述
	`file`	`STRING`	数据导出到的文件名。
	`source`	`STRING`	导出数据的摘要。
	`format`	`STRING`	文件的导出格式。
	`节点`	`INTEGER（整数）`	已导出节点的数量。
	`relationships`	`INTEGER（整数）`	已导出关系的数量。
	`属性`	`INTEGER（整数）`	已导出属性的数量。
	`time`	`INTEGER（整数）`	导出所花费的时间。
	`rows`	`INTEGER（整数）`	返回的行数。
	`batchSize`	`INTEGER（整数）`	导出过程执行的批处理大小。
	`batches`	`INTEGER（整数）`	导出过程执行的批次数。
	`done`	`布尔值 (BOOLEAN)`	导出是否成功执行。
	`data`	`ANY`	导出返回的数据。

用法示例

本节中的示例基于以下示例图

CREATE (TheMatrix:Movie {title:'The Matrix', released:1999, tagline:'Welcome to the Real World'})
CREATE (Keanu:Person {name:'Keanu Reeves', born:1964})
CREATE (Carrie:Person {name:'Carrie-Anne Moss', born:1967})
CREATE (Laurence:Person {name:'Laurence Fishburne', born:1961})
CREATE (Hugo:Person {name:'Hugo Weaving', born:1960})
CREATE (LillyW:Person {name:'Lilly Wachowski', born:1967})
CREATE (LanaW:Person {name:'Lana Wachowski', born:1965})
CREATE (JoelS:Person {name:'Joel Silver', born:1952})
CREATE
(Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrix),
(Carrie)-[:ACTED_IN {roles:['Trinity']}]->(TheMatrix),
(Laurence)-[:ACTED_IN {roles:['Morpheus']}]->(TheMatrix),
(Hugo)-[:ACTED_IN {roles:['Agent Smith']}]->(TheMatrix),
(LillyW)-[:DIRECTED]->(TheMatrix),
(LanaW)-[:DIRECTED]->(TheMatrix),
(JoelS)-[:PRODUCED]->(TheMatrix);

下方的 Neo4j Browser 可视化显示了导入的图

apoc.export.csv.data 过程将指定的节点和关系导出为 CSV 文件或数据流。

以下查询将所有带有 :Person 标签且 name 属性以 L 开头的节点导出到文件 movies-l.csv：

MATCH (person:Person)
WHERE person.name STARTS WITH "L"
WITH collect(person) AS people
CALL apoc.export.csv.data(people, [], "movies-l.csv", {})
YIELD file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data
RETURN file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data

结果
file	source	format	节点	relationships	属性	time	rows	batchSize	batches	done	data
"movies-l.csv"	"data: nodes(3), rels(0)"	"csv"	3	0	6	2	3	20000	1	TRUE	NULL

movies-l.csv 的内容如下所示

"_id","_labels","born","name","_start","_end","_type"
"191",":Person","1961","Laurence Fishburne",,,
"193",":Person","1967","Lilly Wachowski",,,
"194",":Person","1965","Lana Wachowski",,,

以下查询将所有 ACTED_IN 关系以及该关系两侧带有 Person 和 Movie 标签的节点导出到文件 movies-actedIn.csv 中

MATCH (person:Person)-[actedIn:ACTED_IN]->(movie:Movie)
WITH collect(DISTINCT person) AS people, collect(DISTINCT movie) AS movies, collect(actedIn) AS actedInRels
CALL apoc.export.csv.data(people + movies, actedInRels, "movies-actedIn.csv", {})
YIELD file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data
RETURN file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data

结果
file	source	format	节点	relationships	属性	time	rows	batchSize	batches	done	data
"movies-actedIn.csv"	"data: nodes(5), rels(4)"	"csv"	5	4	15	2	9	20000	1	TRUE	NULL

movies-actedIn.csv 的内容如下所示

"_id","_labels","born","name","released","tagline","title","_start","_end","_type","roles"
"189",":Person","1964","Keanu Reeves","","","",,,,
"190",":Person","1967","Carrie-Anne Moss","","","",,,,
"191",":Person","1961","Laurence Fishburne","","","",,,,
"192",":Person","1960","Hugo Weaving","","","",,,,
"188",":Movie","","","1999","Welcome to the Real World","The Matrix",,,,
,,,,,,,"189","188","ACTED_IN","[""Neo""]"
,,,,,,,"190","188","ACTED_IN","[""Trinity""]"
,,,,,,,"191","188","ACTED_IN","[""Morpheus""]"
,,,,,,,"192","188","ACTED_IN","[""Agent Smith""]"

以下查询在 data 列中返回所有 ACTED_IN 关系以及该关系两侧带有 Person 和 Movie 标签的节点的流：

MATCH (person:Person)-[actedIn:ACTED_IN]->(movie:Movie)
WITH collect(DISTINCT person) AS people, collect(DISTINCT movie) AS movies, collect(actedIn) AS actedInRels
CALL apoc.export.csv.data(people + movies, actedInRels, null, {stream: true})
YIELD file, nodes, relationships, properties, data
RETURN file, nodes, relationships, properties, data

结果
file	节点	relationships	属性	data
NULL	5	4	15	"\"_id\",\"_labels\",\"born\",\"name\",\"released\",\"tagline\",\"title\",\"_start\",\"_end\",\"_type\",\"roles\" \"190\",\":Person\",\"1967\",\"Carrie-Anne Moss\",\"\",\"\",\"\",,,, \"189\",\":Person\",\"1964\",\"Keanu Reeves\",\"\",\"\",\"\",,,, \"191\",\":Person\",\"1961\",\"Laurence Fishburne\",\"\",\"\",\"\",,,, \"192\",\":Person\",\"1960\",\"Hugo Weaving\",\"\",\"\",\"\",,,, \"188\",\":Movie\",\"\",\"\",\"1999\",\"Welcome to the Real World\",\"The Matrix\",,,, ,,,,,,,\"189\",\"188\",\"ACTED_IN\",\"[\"\"Neo\"\"]\" ,,,,,,,\"190\",\"188\",\"ACTED_IN\",\"[\"\"Trinity\"\"]\" ,,,,,,,\"191\",\"188\",\"ACTED_IN\",\"[\"\"Morpheus\"\"]\" ,,,,,,,\"192\",\"188\",\"ACTED_IN\",\"[\"\"Agent Smith\"\"]\" "

有关 apoc.export.csv.data 的更多文档

apoc.export.csv.data过程

用法示例

apoc.export.csv.data
过程