apoc.merge.node
过程

详细信息
语法	`apoc.merge.node(labels, identProps [, onCreateProps, onMatchProps ]) :: (node)`
描述	使用给定的动态标签合并指定的 `NODE` 值。
输入参数	名称	类型	描述
	`标签`	`LIST<STRING>`	用于生成的 MERGE 语句的标签列表。
	`identProps`	`MAP`	节点上始终参与合并的属性。
	`onCreateProps`	`MAP`	当节点被创建时合并的属性。默认值为：`{}`。
	`onMatchProps`	`MAP`	当节点被匹配时合并的属性。默认值为：`{}`。
返回参数	名称	类型	描述
返回参数	`节点`	`NODE`	更新后的节点。

使用示例

下面的示例展示了合并带有 Person 和 Actor 标签、且 name 属性为 "Tom Hanks" 的节点的等效方法

apoc.merge.node

CALL apoc.merge.node(
  ["Person", "Actor"],
  {name: "Tom Hanks"},
  {created: datetime()},
  {lastSeen: datetime()}
);

MERGE 子句

MERGE (node:Person:Actor {name: "Tom Hanks"})
ON CREATE SET node.created = datetime()
ON MATCH SET node.lastSeen = datetime()
RETURN node;

结果
节点
(:Person:Actor {name: "Tom Hanks", created: 2020-11-24T11:33:39.319Z})

此过程主要用于合并具有动态属性的节点。例如，我们可能希望创建一个节点，其属性作为参数传入。

以下创建了 labels 和 properties 参数

:param labels =>  (["Human", "MovieStar"]);
:param identityProperties => ({name: "Tom Cruise", placeOfBirth: "Syracuse, New York, United States"});

以下示例根据预先定义的参数创建了一个带有标签和属性的节点

CALL apoc.merge.node($labels, $identityProperties);

结果
节点
(:Human:MovieStar {name: "Tom Cruise", placeOfBirth: "Syracuse, New York, United States"})