特征向量中心性 (Eigenvector Centrality)

术语表

有向: 有向特征。该算法在有向图上定义良好。
有向: 有向特征。该算法忽略图的方向。
有向: 有向特征。该算法不能在有向图上运行。
无向: 无向特征。该算法在无向图上定义良好。
无向: 无向特征。该算法忽略图的无向性。
异构节点: 异构节点完全支持。该算法有能力区分不同类型的节点。
异构节点: 异构节点允许。该算法平等对待所有选定的节点，无论其标签如何。
异构关系: 异构关系完全支持。该算法有能力区分不同类型的关系。
异构关系: 异构关系允许。该算法平等对待所有选定的关系，无论其类型如何。
加权关系: 加权特征。该算法支持将关系属性用作权重，通过 relationshipWeightProperty 配置参数指定。
加权关系: 加权特征。该算法将每个关系视为同等重要，忽略任何关系权重值。
节点属性: 节点属性特征。该算法使用节点属性。

简介

特征向量中心度是一种衡量节点传递性影响力的算法。相比于来自低分节点的连接，来自高分节点的连接对目标节点得分的贡献更大。高特征向量得分意味着该节点连接了许多同样拥有高得分的节点。

该算法计算与最大绝对特征值相关的特征向量。为了计算该特征值，算法应用了幂迭代 (power iteration) 方法。在每次迭代中，每个节点的中心度得分都从其入站邻居的得分中导出。在幂迭代方法中，特征向量在每次迭代后都会进行 L2 归一化，因此默认情况下结果即为归一化结果。

PageRank 算法是特征向量中心度的一个变体，增加了跳转概率。

注意事项

在使用特征向量中心度算法时，需要注意以下事项：

没有入站关系的节点的中心度得分将收敛于 0。
由于缺乏度数归一化，高入度节点对其邻居得分的影响非常大。

语法

本节介绍在每种执行模式下运行特征向量中心度算法的语法。我们描述的是命名图版本的语法。要了解更多通用语法变体，请参阅语法概述。

各模式下的特征向量中心度语法

在命名图上以流 (stream) 模式运行特征向量中心度。

CALL gds.eigenvector.stream(
  graphName: String,
  configuration: Map
)
YIELD
  nodeId: Integer,
  score: Float

表 1. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 2. 配置
名称	类型	默认	可选	描述
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。具有任何给定标签的节点都将被包含。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。具有任何给定类型的关系都将被包含。
concurrency	整数	`4 ^[1]`	是	用于运行算法的并发线程数。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。
maxIterations	整数	`20`	是	特征向量中心度运行的最大迭代次数。
tolerance	浮点数	`0.0000001`	是	迭代间得分的最小变化量。如果所有得分的变化均小于该容差值，则结果被视为稳定，算法随即返回。
relationshipWeightProperty	字符串	`null`	是	用作权重的关系属性名称。如果未指定，算法将作为无权重运行。
sourceNodes	列表、节点或数字	`[]`	是	用于计算个性化特征向量中心度的节点或节点 ID。
scaler	字符串或映射	`None`	是	应用于最终得分的缩放器名称。支持的值包括 `None`、`MinMax`、`Max`、`Mean`、`Log` 和 `StdScore`。如需应用特定的缩放器配置，请使用映射语法：`{scaler: 'name', …}`。
1. 在 GDS 会话中，默认值为可用处理器的数量。

表 3. 结果
名称	类型	描述
nodeId	整数	节点 ID。
score	浮点数	特征向量得分。

在命名图上以统计 (stats) 模式运行特征向量中心度。

CALL gds.eigenvector.stats(
  graphName: String,
  configuration: Map
)
YIELD
  ranIterations: Integer,
  didConverge: Boolean,
  preProcessingMillis: Integer,
  computeMillis: Integer,
  postProcessingMillis: Integer,
  centralityDistribution: Map,
  configuration: Map

表 4. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 5. 配置
名称	类型	默认	可选	描述
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。具有任何给定标签的节点都将被包含。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。具有任何给定类型的关系都将被包含。
concurrency	整数	`4 ^[2]`	是	用于运行算法的并发线程数。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。
maxIterations	整数	`20`	是	特征向量中心度运行的最大迭代次数。
tolerance	浮点数	`0.0000001`	是	迭代间得分的最小变化量。如果所有得分的变化均小于该容差值，则结果被视为稳定，算法随即返回。
relationshipWeightProperty	字符串	`null`	是	用作权重的关系属性名称。如果未指定，算法将作为无权重运行。
sourceNodes	列表、节点或数字	`[]`	是	用于计算个性化特征向量中心度的节点或节点 ID。
scaler	字符串或映射	`None`	是	应用于最终得分的缩放器名称。支持的值包括 `None`、`MinMax`、`Max`、`Mean`、`Log` 和 `StdScore`。如需应用特定的缩放器配置，请使用映射语法：`{scaler: 'name', …}`。
2. 在 GDS 会话中，默认值为可用处理器的数量。

表 6. 结果
名称	类型	描述
ranIterations	整数	运行的迭代次数。
didConverge	布尔值	指示算法是否收敛。
preProcessingMillis	整数	预处理图的毫秒数。
computeMillis	整数	运行算法的毫秒数。
postProcessingMillis	整数	计算 `centralityDistribution` 所需的毫秒数。
centralityDistribution	Map	包含中心性分数的最小值、最大值、平均值以及 p50、p75、p90、p95、p99 和 p999 百分位值的映射。
配置	Map	用于运行算法的配置。

在命名图上以变异 (mutate) 模式运行特征向量中心度。

CALL gds.eigenvector.mutate(
  graphName: String,
  configuration: Map
)
YIELD
  nodePropertiesWritten: Integer,
  ranIterations: Integer,
  didConverge: Boolean,
  preProcessingMillis: Integer,
  computeMillis: Integer,
  postProcessingMillis: Integer,
  mutateMillis: Integer,
  centralityDistribution: Map,
  configuration: Map

表 7. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 8. 配置
名称	类型	默认	可选	描述
mutateProperty	字符串	`不适用`	否	GDS 图中写入得分的节点属性。
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。
concurrency	整数	`4`	是	用于运行算法的并发线程数。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
maxIterations	整数	`20`	是	特征向量中心度运行的最大迭代次数。
tolerance	浮点数	`0.0000001`	是	迭代间得分的最小变化量。如果所有得分的变化均小于该容差值，则结果被视为稳定，算法随即返回。
relationshipWeightProperty	字符串	`null`	是	用作权重的关系属性名称。如果未指定，算法将作为无权重运行。
sourceNodes	列表、节点或数字	`[]`	是	用于计算个性化特征向量中心度的节点或节点 ID。
scaler	字符串或映射	`None`	是	应用于最终得分的缩放器名称。支持的值包括 `None`、`MinMax`、`Max`、`Mean`、`Log` 和 `StdScore`。如需应用特定的缩放器配置，请使用映射语法：`{scaler: 'name', …}`。

表 9. 结果
名称	类型	描述
ranIterations	整数	运行的迭代次数。
didConverge	布尔值	指示算法是否收敛。
preProcessingMillis	整数	预处理图的毫秒数。
computeMillis	整数	运行算法的毫秒数。
postProcessingMillis	整数	计算 `centralityDistribution` 所需的毫秒数。
mutateMillis	整数	向内存中图添加属性的毫秒数。
nodePropertiesWritten	整数	写入内存图中的属性数量。
centralityDistribution	Map	包含中心性分数的最小值、最大值、平均值以及 p50、p75、p90、p95、p99 和 p999 百分位值的映射。
配置	Map	用于运行算法的配置。

在命名图上以写入 (write) 模式运行特征向量中心度。

CALL gds.eigenvector.write(
  graphName: String,
  configuration: Map
)
YIELD
  nodePropertiesWritten: Integer,
  ranIterations: Integer,
  didConverge: Boolean,
  preProcessingMillis: Integer,
  computeMillis: Integer,
  postProcessingMillis: Integer,
  writeMillis: Integer,
  centralityDistribution: Map,
  configuration: Map

表 10. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 11. 配置
名称	类型	默认	可选	描述
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。具有任何给定标签的节点都将被包含。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。具有任何给定类型的关系都将被包含。
concurrency	整数	`4 ^[3]`	是	用于运行算法的并发线程数。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。
writeConcurrency	整数	`'concurrency' 的值`	是	用于将结果写入 Neo4j 的并发线程数。
writeProperty	字符串	`不适用`	否	Neo4j 数据库中写入得分的节点属性。
maxIterations	整数	`20`	是	特征向量中心度运行的最大迭代次数。
tolerance	浮点数	`0.0000001`	是	迭代间得分的最小变化量。如果所有得分的变化均小于该容差值，则结果被视为稳定，算法随即返回。
relationshipWeightProperty	字符串	`null`	是	用作权重的关系属性名称。如果未指定，算法将作为无权重运行。
sourceNodes	列表、节点或数字	`[]`	是	用于计算个性化特征向量中心度的节点或节点 ID。
scaler	字符串或映射	`None`	是	应用于最终得分的缩放器名称。支持的值包括 `None`、`MinMax`、`Max`、`Mean`、`Log` 和 `StdScore`。如需应用特定的缩放器配置，请使用映射语法：`{scaler: 'name', …}`。
3. 在 GDS 会话中，默认值为可用处理器的数量。

表 12. 结果
名称	类型	描述
ranIterations	整数	运行的迭代次数。
didConverge	布尔值	指示算法是否收敛。
preProcessingMillis	整数	预处理图的毫秒数。
computeMillis	整数	运行算法的毫秒数。
postProcessingMillis	整数	计算 `centralityDistribution` 所需的毫秒数。
writeMillis	整数	将结果数据写回的毫秒数。
nodePropertiesWritten	整数	写入 Neo4j 的属性数量。
centralityDistribution	Map	包含中心性分数的最小值、最大值、平均值以及 p50、p75、p90、p95、p99 和 p999 百分位值的映射。
配置	Map	用于运行算法的配置。

示例

以下所有示例应在空数据库中运行。

这些示例将 Cypher 投影作为规范。原生投影将在未来版本中弃用。

在本节中，我们将展示在具体图表上运行特征向量中心度算法的示例。目的是演示结果的样子，并为如何在实际环境中使用该算法提供指导。我们将使用一个小型的网页网络图，其中的节点以特定模式连接。该示例图如下所示：

以下 Cypher 语句将在 Neo4j 数据库中创建示例图：

CREATE
  (home:Page {name:'Home'}),
  (about:Page {name:'About'}),
  (product:Page {name:'Product'}),
  (links:Page {name:'Links'}),
  (a:Page {name:'Site A'}),
  (b:Page {name:'Site B'}),
  (c:Page {name:'Site C'}),
  (d:Page {name:'Site D'}),

  (home)-[:LINKS {weight: 0.2}]->(about),
  (home)-[:LINKS {weight: 0.2}]->(links),
  (home)-[:LINKS {weight: 0.6}]->(product),
  (about)-[:LINKS {weight: 1.0}]->(home),
  (product)-[:LINKS {weight: 1.0}]->(home),
  (a)-[:LINKS {weight: 1.0}]->(home),
  (b)-[:LINKS {weight: 1.0}]->(home),
  (c)-[:LINKS {weight: 1.0}]->(home),
  (d)-[:LINKS {weight: 1.0}]->(home),
  (links)-[:LINKS {weight: 0.8}]->(home),
  (links)-[:LINKS {weight: 0.05}]->(a),
  (links)-[:LINKS {weight: 0.05}]->(b),
  (links)-[:LINKS {weight: 0.05}]->(c),
  (links)-[:LINKS {weight: 0.05}]->(d);

此图表示八个页面，它们相互链接。每个关系都有一个名为 weight 的属性，用于描述关系的重要性。

以下语句将使用 Cypher 投影来投影一个图，并将其以“myGraph”的名称存储在图目录中。

MATCH (source:Page)-[r:LINKS]->(target:Page)
RETURN gds.graph.project(
  'myGraph',
  source,
  target,
  { relationshipProperties: r { .weight } }
)

内存估算

首先，我们将使用 estimate 过程估算运行算法的成本。这可以在任何执行模式下完成。在这个例子中我们将使用 write 模式。估算算法有助于了解在您的图上运行该算法将产生的内存影响。当您随后在其中一种执行模式下真正运行算法时，系统将执行一次估算。如果估算显示执行超出其内存限制的可能性非常高，则禁止执行。要阅读更多关于此的内容，请参阅自动估算和执行阻塞。

有关 estimate 的更多详细信息，请参阅内存估算。

以下内容将估算运行算法所需的内存

CALL gds.eigenvector.write.estimate('myGraph', {
  writeProperty: 'centrality',
  maxIterations: 20
})
YIELD nodeCount, relationshipCount, bytesMin, bytesMax, requiredMemory

表 13. 结果
nodeCount	relationshipCount	bytesMin	bytesMax	requiredMemory
8	14	696	696	"696 字节"

流 (Stream)

在 stream 执行模式下，算法返回每个节点的得分。这使我们能够直接检查结果或在 Cypher 中进行后处理，而不会产生任何副作用。例如，我们可以对结果进行排序，以找到具有最高特征向量得分的节点。

有关 stream 模式的更多详细信息，请参阅流式读取。

以下语句将以 stream 模式运行该算法：

CALL gds.eigenvector.stream('myGraph')
YIELD nodeId, score
RETURN gds.util.asNode(nodeId).name AS name, score
ORDER BY score DESC, name ASC

表 14. 结果
名称 (name)	score
"Home"	0.7465574981728249
"About"	0.33997520529777137
"Links"	0.33997520529777137
"Product"	0.33997520529777137
"Site A"	0.15484062876886298
"Site B"	0.15484062876886298
"Site C"	0.15484062876886298
"Site D"	0.15484062876886298

上述查询以 unweighted（无权重）方式运行 stream 模式下的算法。下面可以找到加权图的示例。

统计 (Stats)

在 stats 执行模式下，算法返回一行包含算法结果摘要的数据。例如，特征向量统计会返回中心度直方图，可用于监控所有计算节点的中心度得分分布。此执行模式没有任何副作用。通过检查 computeMillis 返回项，对于评估算法性能很有用。在下面的示例中，我们将省略返回的时间信息。过程的完整签名可以在语法部分找到。

有关 stats 模式的更多详细信息，请参阅统计。

以下内容将运行该算法并返回关于中心度得分的统计信息。

CALL gds.eigenvector.stats('myGraph', {
  maxIterations: 20
})
YIELD centralityDistribution
RETURN centralityDistribution.max AS max

表 15. 结果
最大值
0.7465591431

变异 (Mutate)

mutate 执行模式扩展了 stats 模式，并产生一个重要的副作用：使用包含该节点得分的新节点属性来更新命名图。新属性的名称通过强制配置参数 mutateProperty 指定。结果是一行总结信息，类似于 stats，但包含一些额外的指标。当结合使用多种算法时，mutate 模式特别有用。

有关 mutate 模式的更多详细信息，请参阅变更。

以下语句将以 mutate 模式运行该算法：

CALL gds.eigenvector.mutate('myGraph', {
  maxIterations: 20,
  mutateProperty: 'centrality'
})
YIELD nodePropertiesWritten, ranIterations

表 16. 结果
nodePropertiesWritten	ranIterations
`8`	`20`

写入 (Write)

write 执行模式扩展了 stats 模式，并产生一个重要的副作用：将每个节点的得分作为属性写入 Neo4j 数据库。新属性的名称通过强制配置参数 writeProperty 指定。结果是一行总结信息，类似于 stats，但包含一些额外的指标。write 模式支持将结果直接持久化到数据库中。

有关 write 模式的更多详细信息，请参阅写入。

以下语句将以 write 模式运行该算法：

CALL gds.eigenvector.write('myGraph', {
  maxIterations: 20,
  writeProperty: 'centrality'
})
YIELD nodePropertiesWritten, ranIterations

表 17. 结果
nodePropertiesWritten	ranIterations
`8`	`20`

加权 (Weighted)

默认情况下，算法认为图的关系是无权重的。要改变这种行为，我们可以使用 relationshipWeightProperty 配置参数。如果设置了该参数，关联的属性值将用作关系权重。在 weighted（加权）情况下，节点发送给其邻居的前一个得分会乘以归一化后的关系权重。请注意，负的关系权重在计算过程中会被忽略。

在以下示例中，我们使用输入图的 weight 属性作为关系权重属性。

以下内容将使用关系权重以 stream 模式运行算法

CALL gds.eigenvector.stream('myGraph', {
  maxIterations: 20,
  relationshipWeightProperty: 'weight'
})
YIELD nodeId, score
RETURN gds.util.asNode(nodeId).name AS name, score
ORDER BY score DESC, name ASC

表 18. 结果
名称 (name)	score
"Home"	0.8328163407319487
"Product"	0.5004775834976313
"About"	0.1668258611658771
"Links"	0.1668258611658771
"Site A"	0.008327591469710233
"Site B"	0.008327591469710233
"Site C"	0.008327591469710233
"Site D"	0.008327591469710233

与无权重示例一样，“Home”节点的得分最高。相反，“Product”现在的得分是第二高，而不是第四高。

我们使用 stream 模式来说明如何以 weighted 方式运行算法，但是，所有算法模式都支持 relationshipWeightProperty 配置参数。

容差 (Tolerance)

tolerance 配置参数表示迭代之间得分的最小变化量。如果所有得分的变化均小于配置的容差，迭代将中止并被视为已收敛。请注意，设置较高的容差会导致更早收敛，但也会降低中心度得分的准确性。

以下内容将使用高 tolerance 值以 stream 模式运行算法

CALL gds.eigenvector.stream('myGraph', {
  maxIterations: 20,
  tolerance: 0.1
})
YIELD nodeId, score
RETURN gds.util.asNode(nodeId).name AS name, score
ORDER BY score DESC, name ASC

表 19. 结果
名称 (name)	score
"Home"	0.7108273818583551
"About"	0.3719400001993262
"Links"	0.3719400001993262
"Product"	0.3719400001993262
"Site A"	0.14116155811301126
"Site B"	0.14116155811301126
"Site C"	0.14116155811301126
"Site D"	0.14116155811301126

我们使用 tolerance: 0.1，与 stream 示例相比，结果略有不同。但是，计算在三次迭代后收敛，我们已经可以观察到得分结果中的趋势。

个性化特征向量中心度

个性化特征向量中心度是特征向量中心度的一种变体，它偏向于一组 sourceNodes。默认情况下，幂迭代对所有节点以相同的值开始：1 / |V|。对于给定的源节点集 S，每个源节点的初始值设置为 1 / |S|，其余所有节点设置为 0。

以下示例展示了如何运行以“Site A”为中心的特征向量中心度。

以下命令将运行算法并流式传输结果

MATCH (siteA:Page {name: 'Site A'}), (siteB:Page {name: 'Site B'})
CALL gds.eigenvector.stream('myGraph', {
  maxIterations: 20,
  sourceNodes: [siteA, siteB]
})
YIELD nodeId, score
RETURN gds.util.asNode(nodeId).name AS name, score
ORDER BY score DESC, name ASC

表 20. 结果
名称 (name)	score
"Home"	0.7465645391567868
"About"	0.33997203172449453
"Links"	0.33997203172449453
"Product"	0.33997203172449453
"Site A"	0.15483736775159632
"Site B"	0.15483736775159632
"Site C"	0.15483736775159632
"Site D"	0.15483736775159632

缩放中心度得分

在内部，中心度得分在每次迭代后使用 L2 归一化进行缩放。因此，最终值已经是归一化的。此行为无法更改，因为它是幂迭代方法的一部分。

但是，若要将最终得分的归一化作为算法执行的一部分，可以使用 scaler 配置参数。所有可用缩放器的说明可以在 scaleProperties 过程的文档中找到。

以下内容将以 stream 模式运行算法并返回归一化结果

CALL gds.eigenvector.stream('myGraph', {
  scaler: "MINMAX"
})
YIELD nodeId, score
RETURN gds.util.asNode(nodeId).name AS name, score
ORDER BY score DESC, name ASC

表 21. 结果
名称 (name)	score
"Home"	1.0
"About"	0.312876962110942
"Links"	0.312876962110942
"Product"	0.312876962110942
"Site A"	0.0
"Site B"	0.0
"Site C"	0.0
"Site D"	0.0

将结果与 stream 示例进行比较，我们可以看到得分的相对顺序是相同的。