关节点 (Articulation Points)

术语表

有向: 有向特征。该算法在有向图上定义良好。
有向: 有向特征。该算法忽略图的方向。
有向: 有向特征。该算法不能在有向图上运行。
无向: 无向特征。该算法在无向图上定义良好。
无向: 无向特征。该算法忽略图的无向性。
异构节点: 异构节点完全支持。该算法有能力区分不同类型的节点。
异构节点: 异构节点允许。该算法平等对待所有选定的节点，无论其标签如何。
异构关系: 异构关系完全支持。该算法有能力区分不同类型的关系。
异构关系: 异构关系允许。该算法平等对待所有选定的关系，无论其类型如何。
加权关系: 加权特征。该算法支持将关系属性用作权重，通过 relationshipWeightProperty 配置参数指定。
加权关系: 加权特征。该算法将每个关系视为同等重要，忽略任何关系权重值。
节点属性: 节点属性特征。该算法使用节点属性。

简介

在给定图中，关节点是指删除后会增加图中连通分量数量的节点。Neo4j GDS 库提供了一种高效的线性时间序列算法来计算图中的所有关节点。

语法

本节介绍在每种执行模式下运行关节点算法所使用的语法。我们描述的是命名图变体的语法。要了解有关通用语法变体的更多信息，请参阅语法概述。

各模式下的关节点语法

在命名图上以流（stream）模式运行关节点算法。

CALL gds.articulationPoints.stream(
  graphName: String,
  configuration: Map
)
YIELD
  nodeId: Integer,
 resultingComponents: Map

表 1. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 2. 配置
名称	类型	默认	可选	描述
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。具有任何给定标签的节点都将被包含。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。具有任何给定类型的关系都将被包含。
concurrency	整数	`1`	是	该算法为单线程，更改并发参数对运行时没有影响。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。

表 3. 结果
名称	类型	描述
nodeId	整数	代表关节点的节点 ID。
resultingComponents	Map	一个包含三个值的映射：删除 `nodeId` 后创建的组件数量，以及它们的大小（最小值和最大值），分别存储在键 `count`、`min`、`max` 中。

在命名图上以统计（stats）模式运行关节点算法。

CALL gds.articulationPoints.stats(
  graphName: String,
  configuration: Map
)
YIELD
  computeMillis: Integer,
  articulationPointCount: Integer,
  configuration: Map

表 4. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 5. 配置
名称	类型	默认	可选	描述
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。具有任何给定标签的节点都将被包含。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。具有任何给定类型的关系都将被包含。
concurrency	整数	`1`	是	该算法为单线程，更改并发参数对运行时没有影响。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。

表 6. 结果
名称	类型	描述
computeMillis	整数	运行算法的毫秒数。
articulationPointCount	整数	图中关节点的计数。
配置	Map	用于运行算法的配置。

在命名图上以变异（mutate）模式运行关节点算法。

CALL gds.articulationPoints.mutate(
  graphName: String,
  configuration: Map
)
YIELD
  mutateMillis: Integer,
  nodePropertiesWritten: Integer,
  computeMillis: Integer,
  articulationPointCount: Integer,
  configuration: Map

表 7. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 8. 配置
名称	类型	默认	可选	描述
mutateProperty	字符串	`不适用`	否	写入节点属性的 GDS 图中的节点属性名称。
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。
concurrency	整数	`4`	是	用于运行算法的并发线程数。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。

表 9. 结果
名称	类型	描述
mutateMillis	整数	向投影图添加属性的毫秒数。
nodePropertiesWritten	整数	添加到投影图中的属性数量。
computeMillis	整数	运行算法的毫秒数。
articulationPointCount	整数	图中关节点的计数。
配置	Map	用于运行算法的配置。

在命名图上以写入（write）模式运行关节点算法。

CALL gds.articulationPoints.write(
  graphName: String,
  configuration: Map
)
YIELD
  writeMillis: Integer,
  nodePropertiesWritten: Integer,
  computeMillis: Integer,
  articulationPointCount: Integer,
  configuration: Map

表 10. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 11. 配置
名称	类型	默认	可选	描述
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。具有任何给定标签的节点都将被包含。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。具有任何给定类型的关系都将被包含。
concurrency	整数	`1`	是	该算法为单线程，更改并发参数对运行时没有影响。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。
writeConcurrency	整数	`'concurrency' 的值`	是	用于将结果写入 Neo4j 的并发线程数。
writeProperty	字符串	`不适用`	否	写入节点属性的 Neo4j 数据库中的节点属性名称。

表 12. 结果
名称	类型	描述
writeMillis	整数	向 Neo4j 数据库添加属性所花费的毫秒数。
nodePropertiesWritten	整数	添加到 Neo4j 数据库的属性数量。
computeMillis	整数	运行算法的毫秒数。
articulationPointCount	整数	图中关节点的计数。
配置	Map	用于运行算法的配置。

示例

以下所有示例应在空数据库中运行。

这些示例将 Cypher 投影作为规范。原生投影将在未来版本中弃用。

在本节中，我们将展示在具体图上运行关节点算法的示例。目的是为了演示结果的样子，并为如何在实际环境中使用该算法提供指导。我们将使用一个小型社交网络图（其中少数节点以特定模式连接）来进行演示。该示例图如下所示：

以下 Cypher 语句将在 Neo4j 数据库中创建示例图：

CREATE
  (nAlice:User {name: 'Alice'}),
  (nBridget:User {name: 'Bridget'}),
  (nCharles:User {name: 'Charles'}),
  (nDoug:User {name: 'Doug'}),
  (nMark:User {name: 'Mark'}),
  (nMichael:User {name: 'Michael'}),

  (nAlice)-[:LINK]->(nBridget),
  (nAlice)-[:LINK]->(nCharles),
  (nCharles)-[:LINK]->(nBridget),

  (nAlice)-[:LINK]->(nDoug),

  (nMark)-[:LINK]->(nDoug),
  (nMark)-[:LINK]->(nMichael),
  (nMichael)-[:LINK]->(nDoug);

该图包含两个紧密连接的 用户 (Users) 集群。在这些集群之间只有一条边。

以下语句将使用 Cypher 投影来投影一个图，并将其以“myGraph”的名称存储在图目录中。

MATCH (source:User)-[r:LINK]->(target:User)
RETURN gds.graph.project(
  'myGraph',
  source,
  target,
  {},
  { undirectedRelationshipTypes: ['*'] }
)

内存估算

首先，我们将使用 estimate 过程来估算运行该算法的成本。这可以在任何执行模式下完成。在本示例中，我们将使用 stream 模式。估算算法有助于了解在图上运行算法对内存的影响。当您稍后在其中一种执行模式下实际运行算法时，系统将执行一次估算。如果估算显示执行超出内存限制的可能性非常高，则禁止执行。要了解更多信息，请参阅自动估算与执行阻塞。

有关 estimate 的更多详细信息，请参阅内存估算。

以下内容将估算运行算法所需的内存

CALL gds.articulationPoints.stream.estimate('myGraph', {})
YIELD nodeCount, relationshipCount, bytesMin, bytesMax, requiredMemory

表 13. 结果
nodeCount	relationshipCount	bytesMin	bytesMax	requiredMemory
6	14	1448	1448	"1448 字节"

流 (Stream)

在 stream 执行模式下，算法返回每个节点的节点属性。这使我们能够直接检查结果，或在 Cypher 中进行后处理，而不会产生任何副作用。

有关 stream 模式的更多详细信息，请参阅流式读取。

以下语句将以 stream 模式运行该算法：

CALL gds.articulationPoints.stream('myGraph')
YIELD nodeId, resultingComponents
RETURN gds.util.asNode(nodeId).name AS name,resultingComponents
ORDER BY name ASC

表 14. 结果
名称 (name)	resultingComponents
"Alice"	{count=2, max=3, min=2}
“Doug”	{count=2, max=3, min=2}

统计 (Stats)

在 stats 执行模式下，算法返回单行结果，其中包含算法执行的摘要。此执行模式没有任何副作用。它对于通过检查 computeMillis 返回项来评估算法性能非常有用。在下面的示例中，我们将省略返回的时间信息。过程的完整签名可以在语法章节中找到。

有关 stats 模式的更多详细信息，请参阅统计。

以下语句将以 stats 模式运行该算法：

CALL gds.articulationPoints.stats('myGraph',{})
YIELD articulationPointCount

表 15. 结果
articulationPointCount
2

变异 (Mutate)

mutate 模式使用一个新的节点属性更新命名图，该属性指示节点是否为关节点。这是通过设置 0,1 值来实现的，其中 1 表示该节点是关节点。新属性的名称使用强制配置参数 mutateProperty 指定。结果是单行摘要，类似于 stats，但包含一些额外的指标。

以下语句将以 mutate 模式运行该算法：

CALL gds.articulationPoints.mutate('myGraph', { mutateProperty: 'articulationPoint'})
YIELD articulationPointCount

表 16. 结果
articulationPointCount
2

写入 (Write)

write 模式使用一个新的节点属性更新 Neo4j 图，该属性指示节点是否为关节点。这是通过设置 0,1 值来实现的，其中 1 表示该节点是关节点。新属性的名称使用强制配置参数 writeProperty 指定。结果是单行摘要，类似于 stats，但包含一些额外的指标。当结合使用多个算法时，mutate 模式特别有用。

以下语句将以 write 模式运行该算法：

CALL gds.articulationPoints.write('myGraph', { writeProperty: 'articulationPoint'})
YIELD articulationPointCount

表 17. 结果
articulationPointCount
2

然后，我们可以查询 Neo4j 以查看关节点

MATCH (n { articulationPoint: 1 }) RETURN n.name AS name ORDER BY name ASC

表 18. 结果
名称 (name)
"Alice"
“Doug”

或者我们可以查询 Neo4j 以查看不是关节点的节点

MATCH (n { articulationPoint: 0 }) RETURN n.name AS name ORDER BY name ASC

表 19. 结果
名称 (name)
“Bridget”
“Charles”
“Mark”
“Michael”