桥 (Bridges)

术语表

有向: 有向特征。该算法在有向图上定义良好。
有向: 有向特征。该算法忽略图的方向。
有向: 有向特征。该算法不能在有向图上运行。
无向: 无向特征。该算法在无向图上定义良好。
无向: 无向特征。该算法忽略图的无向性。
异构节点: 异构节点完全支持。该算法有能力区分不同类型的节点。
异构节点: 异构节点允许。该算法平等对待所有选定的节点，无论其标签如何。
异构关系: 异构关系完全支持。该算法有能力区分不同类型的关系。
异构关系: 异构关系允许。该算法平等对待所有选定的关系，无论其类型如何。
加权关系: 加权特征。该算法支持将关系属性用作权重，通过 relationshipWeightProperty 配置参数指定。
加权关系: 加权特征。该算法将每个关系视为同等重要，忽略任何关系权重值。
节点属性: 节点属性特征。该算法使用节点属性。

简介

在给定图中，桥（Bridge）是指这样一种关系：移除该关系会导致图中连通分量的数量增加。等价地说，当且仅当某关系不包含在任何环（cycle）中时，它才可能是桥。Neo4j GDS 库提供了一种高效的线性时间顺序算法来计算图中的所有桥。

有关此算法的更多信息，请参阅

桥（图论）

语法

本节介绍在每种执行模式下运行 Bridges 算法所使用的语法。我们将描述命名图变体的语法。要了解更多关于通用语法变体的信息，请参阅语法概述。

不同模式下的 Bridges 语法

在命名图上以流（stream）模式运行 Bridges。

CALL gds.bridges.stream(
  graphName: String,
  configuration: Map
)
YIELD
  from: Integer,
  to: Integer
  remainingSizes: List of Long

表 1. 参数
名称	类型	默认	可选	描述
graphName	字符串	`不适用`	否	存储在目录中的图的名称。
配置	Map	`{}`	是	算法特定配置和/或图过滤配置。

表 2. 配置
名称	类型	默认	可选	描述
nodeLabels	字符串列表	`['*']`	是	使用给定的节点标签过滤命名图。具有任何给定标签的节点都将被包含。
relationshipTypes	字符串列表	`['*']`	是	使用给定的关系类型过滤命名图。具有任何给定类型的关系都将被包含。
concurrency	整数	`1`	是	该算法为单线程，更改并发参数对运行时没有影响。
jobId	字符串	`内部生成`	是	可以提供一个 ID 以更轻松地跟踪算法的进度。
logProgress	布尔值	`true`	是	如果禁用，进度百分比将不会被记录。

表 3. 结果
名称	类型	描述
从 (from)	整数	起始节点 ID。
转换为	整数	结束节点 ID。
splitComponents（分割分量）	长整型列表	一个包含移除该关系后所得各分量大小的列表。

示例

以下所有示例应在空数据库中运行。

这些示例将 Cypher 投影作为规范。原生投影将在未来版本中弃用。

在本节中，我们将展示在具体图上运行 Bridges 算法的示例。其目的是演示结果的样子，并提供在实际场景中使用该算法的指南。我们将使用一个由少数节点以特定模式连接而成的小型社交网络图来进行演示。示例图如下所示：

以下 Cypher 语句将在 Neo4j 数据库中创建示例图：

CREATE
  (nAlice:User {name: 'Alice'}),
  (nBridget:User {name: 'Bridget'}),
  (nCharles:User {name: 'Charles'}),
  (nDoug:User {name: 'Doug'}),
  (nMark:User {name: 'Mark'}),
  (nMichael:User {name: 'Michael'}),

  (nAlice)-[:LINK]->(nBridget),
  (nAlice)-[:LINK]->(nCharles),
  (nCharles)-[:LINK]->(nBridget),

  (nAlice)-[:LINK]->(nDoug),

  (nMark)-[:LINK]->(nDoug),
  (nMark)-[:LINK]->(nMichael),
  (nMichael)-[:LINK]->(nDoug);

该图有两个连接紧密的用户（Users）集群。在这两个集群之间存在一条单独的边。

以下语句将使用 Cypher 投影来投影一个图，并将其以“myGraph”的名称存储在图目录中。

MATCH (source:User)-[r:LINK]->(target:User)
RETURN gds.graph.project(
  'myGraph',
  source,
  target,
  {},
  { undirectedRelationshipTypes: ['*'] }
)

内存估算

首先，我们将使用 estimate 过程来估算运行该算法的成本。这可以在任何执行模式下完成。在本示例中，我们将使用 stream 模式。估算算法有助于了解在图上运行算法对内存的影响。当您稍后在其中一种执行模式下实际运行算法时，系统将执行一次估算。如果估算显示执行超出内存限制的可能性非常高，则禁止执行。要了解更多信息，请参阅自动估算与执行阻塞。

有关 estimate 的更多详细信息，请参阅内存估算。

以下内容将估算运行算法所需的内存

CALL gds.bridges.stream.estimate('myGraph', {})
YIELD nodeCount, relationshipCount, bytesMin, bytesMax, requiredMemory

表 4. 结果
nodeCount	relationshipCount	bytesMin	bytesMax	requiredMemory
6	14	1152	1152	“1152 字节”

流（Stream）

在 stream 执行模式下，该算法会返回每条关系的桥接情况。这使我们能够直接检查结果，或在 Cypher 中进行后处理，而不会产生任何副作用。

有关 stream 模式的更多详细信息，请参阅流式读取。

以下语句将以 stream 模式运行该算法：

CALL gds.bridges.stream('myGraph')
YIELD from, to, remainingSizes
RETURN gds.util.asNode(from).name AS fromName, gds.util.asNode(to).name AS toName, remainingSizes
ORDER BY fromName ASC, toName ASC

表 5. 结果
fromName（起始节点名称）	toName（结束节点名称）	remainingSizes（剩余分量大小）
"Alice"	“Doug”	[3, 3]