|| apoc.node.degree - APOC 核心文档 - Neo4j 文档

apoc.node.degree

详情
语法	`apoc.node.degree(node [, relTypes ])`
描述	返回给定 `NODE` 的总度数。
参数	名称	类型	描述
	`node`	`NODE`	要计算其总关系数的节点。
	`relTypes`	`STRING`	限制关系计数的类型。关系类型使用 APOC 的关系方向模式语法表示；`[<]RELATIONSHIP_TYPE1[>]\|[<]RELATIONSHIP_TYPE2[>]\|…`。默认值为：``。
返回	`INTEGER`

用法示例

本节示例基于以下示例图

MERGE (michael:Person {name: "Michael"})
WITH michael
CALL {
    WITH michael
    UNWIND range(0, 100) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:KNOWS]-(p)
    RETURN count(*) AS friends
}

CALL {
    WITH michael
    UNWIND range(0, 50) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:FOLLOWS]-(p)
    RETURN count(*) AS follows
}

RETURN friends, follows;

结果
朋友	关注
101	51

apoc.node.degree

MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree(p) AS output

使用 Cypher 的 count() 和模式匹配

MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)--() } AS output

结果
输出
152

apoc.node.degree

MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree(p, "FOLLOWS>") AS output

使用 Cypher 的 count() 和模式匹配

MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)-[:FOLLOWS]->() } AS output

结果
输出
51

apoc.node.degree

MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree(p, "<KNOWS") AS output

使用 Cypher 的 COUNT 子查询和模式匹配

MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)<-[:KNOWS]-() } AS output

结果
输出
0