|| apoc.graph.from - APOC 核心文档 - Neo4j 文档

apoc.graph.from

此过程返回虚拟节点和关系，它们只能通过其他 APOC 过程访问。更多信息请参阅虚拟节点与关系 (图投影)。

详情
语法	`apoc.graph.from(data, name, props) :: (graph)`
描述	通过从给定数据中提取所有 `NODE` 和 `RELATIONSHIP` 值来生成虚拟子图。
输入参数	名称	类型	描述
	`data`	`任意`	要从中提取节点和关系的对象。它可以是以下类型：NODE \| RELATIONSHIP \| PATH \| LIST<ANY>。
	`name`	`字符串`	生成图的名称。
	`props`	`映射`	生成图中包含的属性。
返回参数	名称	类型	描述
返回参数	`graph`	`映射`	生成的图。

使用示例

本节中的示例基于以下示例图

CREATE (TheMatrix:Movie {title:'The Matrix', released:1999, tagline:'Welcome to the Real World'})
CREATE (Keanu:Person {name:'Keanu Reeves', born:1964})
CREATE (Carrie:Person {name:'Carrie-Anne Moss', born:1967})
CREATE (Laurence:Person {name:'Laurence Fishburne', born:1961})
CREATE (Hugo:Person {name:'Hugo Weaving', born:1960})
CREATE (LillyW:Person {name:'Lilly Wachowski', born:1967})
CREATE (LanaW:Person {name:'Lana Wachowski', born:1965})
CREATE (JoelS:Person {name:'Joel Silver', born:1952})
CREATE
(Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrix),
(Carrie)-[:ACTED_IN {roles:['Trinity']}]->(TheMatrix),
(Laurence)-[:ACTED_IN {roles:['Morpheus']}]->(TheMatrix),
(Hugo)-[:ACTED_IN {roles:['Agent Smith']}]->(TheMatrix),
(LillyW)-[:DIRECTED]->(TheMatrix),
(LanaW)-[:DIRECTED]->(TheMatrix),
(JoelS)-[:PRODUCED]->(TheMatrix);

MATCH (m:Movie)
WITH collect(m) AS movies
CALL apoc.graph.from(movies, "movies", {})
YIELD graph AS g
RETURN g;

结果
graph
{name: "movies", relationships: [], nodes: [(:Movie {tagline: "Welcome to the Real World", title: "The Matrix", released: 1999})], properties: {}}

apoc.graph.from 的更多文档