|| apoc.node.degree.in - APOC 核心文档 - Neo4j 文档

apoc.node.degree.in

详情
语法	`apoc.node.degree.in(node [, relTypes ])`
描述	返回连接到给定 `NODE` 的入站 `RELATIONSHIP` 值的总数。
参数	名称	类型	描述
	`node`	`NODE`	要计算入站关系总数的节点。
	`relTypes`	`STRING`	用于限制计数的关系类型。默认值为：``。
返回	`INTEGER`

使用示例

本节示例基于以下示例图

MERGE (michael:Person {name: "Michael"})
WITH michael
CALL {
    WITH michael
    UNWIND range(0, 100) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:KNOWS]-(p)
    RETURN count(*) AS friends
}

CALL {
    WITH michael
    UNWIND range(0, 50) AS id
    MERGE (p:Person {name: "Person" + id})
    MERGE (michael)-[:FOLLOWS]-(p)
    RETURN count(*) AS follows
}

RETURN friends, follows;

结果
朋友	关注
101	51

apoc.node.degree.in

MATCH (p:Person {name: "Michael"})
RETURN apoc.node.degree.in(p) AS output

使用 Cypher 的 COUNT 子查询和模式匹配

MATCH (p:Person {name: "Michael"})
RETURN COUNT { (p)<--() } AS output

结果
输出
0

apoc.node.degree.in

MATCH (p:Person {name: "Person1"})
RETURN apoc.node.degree.in(p) AS output

使用 Cypher 的 COUNT 子查询和模式匹配

MATCH (p:Person {name: "Person1"})
RETURN COUNT { (p)<--() } AS output

结果
输出
2

apoc.node.degree.in

MATCH (p:Person {name: "Person1"})
RETURN apoc.node.degree.in(p, "KNOWS") AS output

使用 Cypher 的 COUNT 子查询和模式匹配

MATCH (p:Person {name: "Person1"})
RETURN COUNT { (p)<-[:KNOWS]-() } AS output

结果
输出
1