apoc.export.csv.data

此过程不被认为是多线程安全运行的。因此，并行运行时不支持此过程。欲了解更多信息，请参阅Cypher 手册 → 并行运行时。

详情
语法	`apoc.export.csv.data(nodes, rels, file, config) :: (file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data)`
描述	将给定的 `NODE` 和 `RELATIONSHIP` 值导出到提供的 CSV 文件。
输入参数	名称	类型	描述
	`nodes`	`LIST<NODE>`	要导出的节点列表。
	`rels`	`LIST<RELATIONSHIP>`	要导出的关系列表。
	`file`	`STRING`	数据将导出到的文件名。
	`config`	`MAP`	`{ stream = false :: BOOLEAN, batchSize = 20000 :: INTEGER, bulkImport = false :: BOOLEAN, timeoutSeconds = 100 :: INTEGER, compression = 'None' :: STRING, charset = 'UTF_8' :: STRING, quotes = 'always' :: ['always', 'none', 'ifNeeded'], differentiateNulls = false :: BOOLEAN, sampling = false :: BOOLEAN, samplingConfig :: MAP }`
返回参数	名称	类型	描述
	`file`	`STRING`	数据导出到的文件名。
	`source`	`STRING`	导出数据的摘要。
	`format`	`STRING`	文件导出的格式。
	`nodes`	`INTEGER`	导出的节点数量。
	`relationships`	`INTEGER`	导出的关系数量。
	`properties`	`INTEGER`	导出的属性数量。
	`time`	`INTEGER`	导出的持续时间。
	`rows`	`INTEGER`	返回的行数。
	`batchSize`	`INTEGER`	导出运行时批次的大小。
	`batches`	`INTEGER`	导出运行时批次的数量。
	`done`	`BOOLEAN`	导出是否成功运行。
	`data`	`ANY`	导出返回的数据。

使用示例

本节中的示例基于以下示例图

CREATE (TheMatrix:Movie {title:'The Matrix', released:1999, tagline:'Welcome to the Real World'})
CREATE (Keanu:Person {name:'Keanu Reeves', born:1964})
CREATE (Carrie:Person {name:'Carrie-Anne Moss', born:1967})
CREATE (Laurence:Person {name:'Laurence Fishburne', born:1961})
CREATE (Hugo:Person {name:'Hugo Weaving', born:1960})
CREATE (LillyW:Person {name:'Lilly Wachowski', born:1967})
CREATE (LanaW:Person {name:'Lana Wachowski', born:1965})
CREATE (JoelS:Person {name:'Joel Silver', born:1952})
CREATE
(Keanu)-[:ACTED_IN {roles:['Neo']}]->(TheMatrix),
(Carrie)-[:ACTED_IN {roles:['Trinity']}]->(TheMatrix),
(Laurence)-[:ACTED_IN {roles:['Morpheus']}]->(TheMatrix),
(Hugo)-[:ACTED_IN {roles:['Agent Smith']}]->(TheMatrix),
(LillyW)-[:DIRECTED]->(TheMatrix),
(LanaW)-[:DIRECTED]->(TheMatrix),
(JoelS)-[:PRODUCED]->(TheMatrix);

下面的 Neo4j Browser 可视化显示了导入的图

apoc.export.csv.data 过程将指定的节点和关系导出到 CSV 文件或作为流。

以下查询将所有带有 :Person 标签且 name 属性以 L 开头的节点导出到文件 movies-l.csv

MATCH (person:Person)
WHERE person.name STARTS WITH "L"
WITH collect(person) AS people
CALL apoc.export.csv.data(people, [], "movies-l.csv", {})
YIELD file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data
RETURN file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data

结果
file	source	format	nodes	relationships	properties	time	rows	batchSize	batches	done	data
"movies-l.csv"	"data: nodes(3), rels(0)"	"csv"	3	0	6	2	3	20000	1	TRUE	NULL

movies-l.csv 的内容如下所示

"_id","_labels","born","name","_start","_end","_type"
"191",":Person","1961","Laurence Fishburne",,,
"193",":Person","1967","Lilly Wachowski",,,
"194",":Person","1965","Lana Wachowski",,,

以下查询将所有 ACTED_IN 关系以及该关系两侧带有 Person 和 Movie 标签的节点导出到文件 movies-actedIn.csv

MATCH (person:Person)-[actedIn:ACTED_IN]->(movie:Movie)
WITH collect(DISTINCT person) AS people, collect(DISTINCT movie) AS movies, collect(actedIn) AS actedInRels
CALL apoc.export.csv.data(people + movies, actedInRels, "movies-actedIn.csv", {})
YIELD file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data
RETURN file, source, format, nodes, relationships, properties, time, rows, batchSize, batches, done, data

结果
file	source	format	nodes	relationships	properties	time	rows	batchSize	batches	done	data
"movies-actedIn.csv"	"data: nodes(5), rels(4)"	"csv"	5	4	15	2	9	20000	1	TRUE	NULL

movies-actedIn.csv 的内容如下所示

"_id","_labels","born","name","released","tagline","title","_start","_end","_type","roles"
"189",":Person","1964","Keanu Reeves","","","",,,,
"190",":Person","1967","Carrie-Anne Moss","","","",,,,
"191",":Person","1961","Laurence Fishburne","","","",,,,
"192",":Person","1960","Hugo Weaving","","","",,,,
"188",":Movie","","","1999","Welcome to the Real World","The Matrix",,,,
,,,,,,,"189","188","ACTED_IN","[""Neo""]"
,,,,,,,"190","188","ACTED_IN","[""Trinity""]"
,,,,,,,"191","188","ACTED_IN","[""Morpheus""]"
,,,,,,,"192","188","ACTED_IN","[""Agent Smith""]"

以下查询返回一个包含所有 ACTED_IN 关系以及该关系两侧带有 Person 和 Movie 标签的节点的流，这些数据位于 data 列中

MATCH (person:Person)-[actedIn:ACTED_IN]->(movie:Movie)
WITH collect(DISTINCT person) AS people, collect(DISTINCT movie) AS movies, collect(actedIn) AS actedInRels
CALL apoc.export.csv.data(people + movies, actedInRels, null, {stream: true})
YIELD file, nodes, relationships, properties, data
RETURN file, nodes, relationships, properties, data

结果
file	nodes	relationships	properties	data
NULL	5	4	15	"\"_id\",\"_labels\",\"born\",\"name\",\"released\",\"tagline\",\"title\",\"_start\",\"_end\",\"_type\",\"roles\" \"190\",\":Person\",\"1967\",\"Carrie-Anne Moss\",\"\",\"\",\"\",,,, \"189\",\":Person\",\"1964\",\"Keanu Reeves\",\"\",\"\",\"\",,,, \"191\",\":Person\",\"1961\",\"Laurence Fishburne\",\"\",\"\",\"\",,,, \"192\",\":Person\",\"1960\",\"Hugo Weaving\",\"\",\"\",\"\",,,, \"188\",\":Movie\",\"\",\"\",\"1999\",\"Welcome to the Real World\",\"The Matrix\",,,, ,,,,,,,\"189\",\"188\",\"ACTED_IN\",\"[\"\"Neo\"\"]\" ,,,,,,,\"190\",\"188\",\"ACTED_IN\",\"[\"\"Trinity\"\"]\" ,,,,,,,\"191\",\"188\",\"ACTED_IN\",\"[\"\"Morpheus\"\"]\" ,,,,,,,\"192\",\"188\",\"ACTED_IN\",\"[\"\"Agent Smith\"\"]\" "

更多 apoc.export.csv.data 文档