设置和查询复合数据库
企业版Aura 不可用

本节中的示例使用了两个 Cypher 子句：USE 和 CALL {}。

图设置

要重现本页面的示例，需要进行以下设置：

创建一个标准数据库 movies-latest

CREATE DATABASE `movies-latest`

创建一个组合数据库 cineasts

CREATE COMPOSITE DATABASE cineasts

为组合数据库中的本地数据库创建数据库别名 cineasts.latest

CREATE ALIAS `cineasts`.`latest`
  FOR DATABASE `movies-latest`

为组合数据库中的远程数据库创建数据库别名 cineasts.upcoming

CREATE ALIAS `cineasts`.`upcoming`
  FOR DATABASE upcoming
  AT 'neo4j+s://location:7687'
  USER neo4j
  PASSWORD 'password'

Cypher 5 是 Neo4j 在 2025.05 及之前版本中使用的版本。有关详细信息，请参阅 Cypher® 版本。

创建一个标准数据库 movies-latest

引入于 2025.06

CREATE DATABASE `movies-latest`

创建一个组合数据库 cineasts

CREATE COMPOSITE DATABASE cineasts

为组合数据库中的本地数据库创建数据库别名 cineasts.latest

CREATE ALIAS `cineasts.latest`
  FOR DATABASE `movies-latest`

为组合数据库中的远程数据库创建数据库别名 cineasts.upcoming

CREATE ALIAS `cineasts.upcoming`
  FOR DATABASE upcoming
  AT 'neo4j+s://location:7687'
  USER neo4j
  PASSWORD 'password'

有关组合数据库及组合数据库中数据库别名的更多信息，请参阅概念以及管理组合数据库中的数据库别名。

图选择

提交给组合数据库的查询可能包含多个 USE 子句，将查询的不同部分定向到不同的组成图。

每个组成图都以将其引入组合数据库的别名命名。

查询单个图

示例 1. 从单个图中读取并返回数据

USE cineasts.latest
MATCH (movie:Movie)
RETURN movie.title AS title

查询开头的 USE 子句为所有后续子句选择了 cineasts.latest 图。MATCH 操作在该图上执行。

查询多个图

示例 2. 从两个图中读取并返回数据

USE cineasts.latest
MATCH (movie:Movie)
RETURN movie.title AS title
  UNION
USE cineasts.upcoming
MATCH (movie:Movie)
RETURN movie.title AS title

UNION 查询的第一部分选择了 cineasts.latest 图，第二部分选择了 cineasts.upcoming 图。

动态图访问

查询还可以使用 USE graph.byName(graphName) 格式动态选择组成图。

示例 3. 从动态选择的图中读取并返回数据

UNWIND ['cineasts.latest', 'cineasts.upcoming'] AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN movie.title AS title

在上面的示例中，访问图数据的查询部分 MATCH (movie:Movie) 被封装在一个带有动态 USE 子句的子查询中。UNWIND 用于获取图的名称，每一行对应一个名称。CALL {} 子查询对每个输入行执行一次。在本例中，一次选择 cineasts.latest，另一次选择 cineasts.upcoming。

列出图

内置函数 graph.names() 返回一个包含当前组合数据库上所有组成图名称的列表。

示例 4. graph.names() 函数

UNWIND graph.names() AS graphName
RETURN graphName

+---------------------+
| graphName           |
+---------------------+
| "cineasts.latest"   |
| "cineasts.upcoming" |
+---------------------+

此函数返回的名称可用于动态图访问。

示例 5. 从所有图中读取并返回数据

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN movie.title

查询结果聚合

示例 6. 获取来自所有图的所有电影的最早发行年份

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie.released AS released
}
RETURN min(released) AS earliest

子查询从每个组成图中返回每部电影的 released 属性。主查询末尾的 RETURN 对完整结果进行聚合，以计算全局最小值。

关联子查询

此查询查找 cineasts.upcoming 中所有计划在与 cineasts.latest 中时长最长的电影相同月份发行的电影。

示例 7. 关联子查询

CALL {
  USE cineasts.latest
  MATCH (movie:Movie)
  RETURN movie.releasedMonth AS monthOfLongest
    ORDER BY movie.runningTime DESC
    LIMIT 1
}
CALL {
  USE cineasts.upcoming
  WITH monthOfLongest
  MATCH (movie:Movie)
  WHERE movie.releasedMonth = monthOfLongest
  RETURN movie
}
RETURN movie

查询的第一部分从 cineasts.latest 中查找运行时间最长的电影，并返回其发行月份。查询的第二部分查找 cineasts.upcoming 中所有符合条件的电影并返回它们。子查询使用 WITH monthOfLongest 导入 monthOfLongest 变量，使其可被访问。

更新

组合数据库查询可以对组成图执行更新。

示例 8. 组成图更新

USE cineasts.upcoming
CREATE (:Movie {title: 'Dune: Part Two'})

每个事务只能对单个组成图执行更新。

示例 9. 多图更新将会失败

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  CREATE (:Movie {title: 'The Flash'})
}

Writing to more than one database per transaction is not allowed.

限制

组合数据库上的查询存在一些限制。

图访问操作

考虑一个组合数据库查询

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN movie

在这里，外部子句（即 UNWIND、CALL 本身以及最终的 RETURN）出现在查询的根作用域中，没有指定特定的图。在未指定图的作用域中的子句或表达式不得进行图访问。

以下组合数据库查询是无效的，因为 [p=(movie)-→() | p] AS paths 是查询根作用域中的图访问操作

UNWIND graph.names() AS graphName
CALL {
  USE graph.byName(graphName)
  MATCH (movie:Movie)
  RETURN movie
}
RETURN [p=(movie)-->() | p] AS paths

查看图访问操作示例

RETURN 1 + 2 AS number
WITH node.property AS val

嵌套 `USE` 子句

内部作用域必须使用与其外部作用域相同的图

USE cineasts.latest
MATCH (n)
CALL {
  USE cineasts.upcoming
  MATCH (m)
  RETURN m
}
RETURN n, m

Nested subqueries must use the same graph as their parent query.
Attempted to access graph cineasts.upcoming
"    USE cineasts.upcoming"
     ^

没有 USE 子句的子查询可以嵌套。它们会从外部作用域继承指定的图。

CALL {
  USE cineasts.upcoming
  CALL {
    MATCH (m:Movie)
    RETURN m
  }
  RETURN m
}
RETURN m

Cypher 运行时

当查询提交给组合数据库时，查询的不同部分可能使用不同的运行时运行。在未指定图的作用域中的子句或表达式使用 slotted 运行时运行。定向到不同组成图的查询部分使用该图的默认运行时，如果指定了 Cypher 查询选项，则遵循这些选项。

内置图函数

图函数位于 graph 命名空间中。下表描述了这些函数

表 1. 内置图函数
函数	说明
`graph.names()`	提供当前组合数据库上所有组成图的名称列表。
`graph.byName(graphName)`	与 `USE` 子句结合使用，以按名称动态选择组成图。此函数仅支持在 `USE` 子句中使用。
`graph.propertiesByName(graphName)`	返回一个包含与给定图关联的属性的映射。

有关更多信息，请参阅 Cypher 手册中的 图函数。

设置和查询复合数据库企业版Aura 不可用

图设置

图选择