条件表达式 (CASE)

通用条件表达式可以使用 Cypher® 中的 CASE 结构来表示。Cypher 中存在两种 CASE 变体：简单形式（用于将单个表达式与多个值进行比较）和通用形式（用于表达多个条件语句）。

如果您希望在后续子句中使用 CASE 的结果，它只能作为 RETURN 或 WITH 的一部分使用。

示例图

以下图表用于下方的示例

Example graph connecting Person nodes via knows relationships

要重新创建该图，请在空的 Neo4j 数据库中运行以下查询

CREATE
  (alice:Person {name:'Alice', age: 38, eyes: 'brown'}),
  (bob:Person {name: 'Bob', age: 25, eyes: 'blue'}),
  (charlie:Person {name: 'Charlie', age: 53, eyes: 'green'}),
  (daniel:Person {name: 'Daniel', eyes: 'brown'}),
  (eskil:Person {name: 'Eskil', age: 41, eyes: 'blue'}),
  (alice)-[:KNOWS]->(bob),
  (alice)-[:KNOWS]->(charlie),
  (bob)-[:KNOWS]->(daniel),
  (charlie)-[:KNOWS]->(daniel),
  (bob)-[:MARRIED]->(eskil)

简单 CASE

简单 CASE 形式用于将单个表达式与多个值进行比较，类似于编程语言中的 switch 结构。表达式由 WHEN 运算符进行评估，直到找到匹配项。如果未找到匹配项，则返回 ELSE 运算符中的表达式。如果没有 ELSE 情况且未找到匹配项，则返回 null。

语法

CASE test
  WHEN value [, value]* THEN result
  [WHEN ...]
  [ELSE default]
END

参数

名称 描述

test

一个表达式。

值

一个其结果将与 test 进行比较的表达式。

结果

如果 value 与 test 匹配，则作为输出返回的表达式。

默认

如果没有值与测试表达式匹配时要返回的表达式。

示例

MATCH (n:Person)
RETURN
CASE n.eyes
  WHEN 'blue'  THEN 1
  WHEN 'brown', 'hazel' THEN 2
  ELSE 3
END AS result, n.eyes
结果 n.eyes

2

"brown"

1

"blue"

3

"green"

2

"brown"

1

"blue"

行：5

扩展简单 CASE

扩展简单 CASE 形式允许明确指定比较运算符。简单 CASE 使用隐含的相等 (=) 比较器。

支持的比较器包括

语法

CASE test
  WHEN [comparisonOperator] value [, [comparisonOperator] value ]* THEN result
  [WHEN ...]
  [ELSE default]
END

参数

名称 描述

test

一个表达式。

comparisonOperator

支持的比较运算符之一。

值

一个使用给定比较运算符将其结果与 test 进行比较的表达式。

结果

如果 value 与 test 匹配，则作为输出返回的表达式。

默认

如果没有值与测试表达式匹配时要返回的表达式。

示例

MATCH (n:Person)
RETURN n.name,
CASE n.age
  WHEN IS NULL, IS NOT TYPED INTEGER | FLOAT THEN "Unknown"
  WHEN = 0, = 1, = 2 THEN "Baby"
  WHEN <= 13 THEN "Child"
  WHEN < 20 THEN "Teenager"
  WHEN < 30 THEN "Young Adult"
  WHEN > 1000 THEN "Immortal"
  ELSE "Adult"
END AS result
n.name 结果

"Alice"

"Adult"

"Bob"

"Young Adult"

"Charlie"

"Adult"

"Daniel"

"Unknown"

"Eskil"

"Adult"

行：5

通用 CASE

通用 CASE 表达式支持多个条件语句，类似于编程语言中的 if-elseif-else 结构。每一行都会按顺序进行评估，直到找到一个 true 值。如果未找到匹配项，则返回 ELSE 运算符中的表达式。如果没有 ELSE 情况且未找到匹配项，则返回 null。

语法

CASE
  WHEN predicate THEN result
  [WHEN ...]
  [ELSE default]
END

参数

名称 描述

predicate

谓词是评估为 BOOLEAN 值的表达式。在这种情况下，将测试谓词以找到有效的替代方案。

结果

如果 predicate 评估为 true，则作为输出返回的表达式。

默认

如果未找到匹配项，则返回 default。

示例

MATCH (n:Person)
RETURN
CASE
  WHEN n.eyes = 'blue' THEN 1
  WHEN n.age < 40      THEN 2
  ELSE 3
END AS result, n.eyes, n.age
结果 n.eyes n.age

2

"brown"

38

1

"blue"

25

3

"green"

53

3

"brown"

null

1

"blue"

41

行：5

带有 null 值的 CASE

处理 null 值时，您可能被迫使用通用 CASE 形式。以下两个示例使用 Daniel 节点的 age 属性（该属性的值为 null）来阐明区别。

简单 CASE
MATCH (n:Person)
RETURN n.name,
CASE n.age  (1)
  WHEN null THEN -1  (2)
  ELSE n.age - 10 (3)
END AS age_10_years_ago
1 n.age 是被评估的表达式。请注意，节点 Daniel 的年龄值为 null。
2 此分支被跳过，因为 null 不等于任何其他值，包括 null 本身。
3 执行过程进入 ELSE 分支，该分支输出 null，因为 n.age - 10 等于 null。
n.name age_10_years_ago

"Alice"

28

"Bob"

15

"Charlie"

43

"Daniel"

null

"Eskil"

31

行：5
通用 CASE
MATCH (n:Person)
RETURN n.name,
CASE  (1)
  WHEN n.age IS NULL THEN -1  (2)
  ELSE n.age - 10
END AS age_10_years_ago
1 如果 CASE 之后未提供表达式，它将以通用形式运行，支持在每个分支中使用谓词表达式。
2 对于节点 Daniel，此谓词表达式的评估结果为 true，因此返回此分支的结果。
n.name age_10_years_ago

"Alice"

28

"Bob"

15

"Charlie"

43

"Daniel"

-1

"Eskil"

31

行：5

有关 null 的更多信息，请参阅 使用 null。

CASE 表达式与后续子句

CASE 表达式的结果可用于设置节点或关系的属性。

MATCH (n:Person)
WITH n,
CASE n.eyes
  WHEN 'blue'  THEN 1
  WHEN 'brown' THEN 2
  ELSE 3
END AS colorCode
SET n.colorCode = colorCode
RETURN n.name, n.colorCode
n.name n.colorCode

"Alice"

2

"Bob"

1

"Charlie"

3

"Daniel"

2

"Eskil"

1

行：5

有关使用 SET 子句的更多信息，请参阅 SET。

进一步考虑

CASE 结果分支在执行前会进行静态检查。这意味着如果某个分支在语义上不正确，即使该分支在运行时可能永远不会被执行，它仍然会抛出异常。

在以下示例中，date 在静态上已知为 STRING 值，因此如果将其作为 DATE 值处理，将会失败。

不允许
WITH "2024-08-05" AS date, "string" AS type
RETURN CASE type
    WHEN "string" THEN datetime(date)
    WHEN "date" THEN datetime({year: date.year, month: date.month, day: date.day})
    ELSE datetime(date)
END AS dateTime
GQLSTATUS 错误链

22N27: 错误: 数据异常 - 无效实体类型。date 的输入 'STRING' 无效。应为 MAP, NODE, RELATIONSHIP, POINT, DURATION, DATE, ZONED TIME, LOCAL TIME, LOCAL DATETIME 或 ZONED DATETIME。

22G03: 错误: 数据异常 - 无效的值类型