apoc.nlp.gcp.entities.graph
过程 Apoc 扩展
为提供的文本创建（虚拟）实体图
安装依赖
NLP 过程依赖于 Kotlin 和客户端库，这些库未包含在 APOC Extended 库中。
这些依赖项包含在 apoc-nlp-dependencies-2025.10.0-all.jar 中，可从 发布页面 下载。下载该文件后，应将其放入 plugins 目录并重启 Neo4j 服务器。
设置 API 密钥
您可以前往 console.cloud.google.com/apis/credentials 生成有权访问 Cloud Natural Language API 的 API 密钥。创建密钥后，我们可以填充并执行以下命令来创建一个包含这些详细信息的参数。
apiKey 参数:param apiKey => ("<api-key-here>")或者，我们可以将这些凭据添加到 apoc.conf 中，并使用静态值存储函数加载它们。
apoc.static.gcp.apiKey=<api-key-here>apoc.conf 中检索 GCP 凭据RETURN apoc.static.getAll("gcp") AS gcp;| gcp |
|---|
{apiKey: "<api-key-here>"} |
使用示例
本节中的示例基于以下示例图
CREATE (:Article {
uri: "/blog/pokegraph-gotta-graph-em-all/",
body: "These days I’m rarely more than a few feet away from my Nintendo Switch and I play board games, card games and role playing games with friends at least once or twice a week. I’ve even organised lunch-time Mario Kart 8 tournaments between the Neo4j European offices!"
});
CREATE (:Article {
uri: "https://en.wikipedia.org/wiki/Nintendo_Switch",
body: "The Nintendo Switch is a video game console developed by Nintendo, released worldwide in most regions on March 3, 2017. It is a hybrid console that can be used as a home console and portable device. The Nintendo Switch was unveiled on October 20, 2016. Nintendo offers a Joy-Con Wheel, a small steering wheel-like unit that a Joy-Con can slot into, allowing it to be used for racing games such as Mario Kart 8."
});我们可以使用此过程自动创建实体图。除了拥有 Entity 标签外，每个实体节点还将根据 type 属性的值拥有另一个标签。默认情况下，返回的是虚拟图。
以下返回 Pokemon 文章的实体虚拟图
MATCH (a:Article {uri: "/blog/pokegraph-gotta-graph-em-all/"})
CALL apoc.nlp.gcp.entities.graph(a, {
key: $apiKey,
nodeProperty: "body",
writeRelationshipType: "ENTITY"
})
YIELD graph AS g
RETURN g;我们可以在 Pokemon 实体图 中查看虚拟图的 Neo4j Browser 可视化效果。
我们可以通过将节点列表传递给该过程，来为多个节点计算实体。
以下返回 Pokemon 和 Nintendo Switch 文章的实体虚拟图
MATCH (a:Article)
WITH collect(a) AS articles
CALL apoc.nlp.gcp.entities.graph(articles, {
key: $apiKey,
nodeProperty: "body",
writeRelationshipType: "ENTITY"
})
YIELD graph AS g
RETURN g;我们可以在 Pokemon 和 Nintendo Switch 实体图 中查看虚拟图的 Neo4j Browser 可视化效果。
在此可视化中，我们还可以看到每个实体节点的评分。该评分代表了实体在整个文档中的重要性。我们可以使用 scoreCutoff 属性为评分指定最小截止值。
以下返回 Pokemon 和 Nintendo Switch 文章的实体虚拟图
MATCH (a:Article)
WITH collect(a) AS articles
CALL apoc.nlp.gcp.entities.graph(articles, {
key: $apiKey,
nodeProperty: "body",
writeRelationshipType: "ENTITY",
scoreCutoff: 0.01
})
YIELD graph AS g
RETURN g;我们可以在 重要性 >= 0.01 的 Pokemon 和 Nintendo Switch 实体图 中查看虚拟图的 Neo4j Browser 可视化效果。
如果我们对这个图感到满意并希望将其持久化到 Neo4j 中，可以通过指定 write: true 配置来实现。
以下创建从文章到每个实体的 HAS_ENTITY 关系
MATCH (a:Article)
WITH collect(a) AS articles
CALL apoc.nlp.gcp.entities.graph(articles, {
key: $apiKey,
nodeProperty: "body",
scoreCutoff: 0.01,
writeRelationshipType: "HAS_ENTITY",
writeRelationshipProperty: "gcpEntityScore",
write: true
})
YIELD graph AS g
RETURN g;然后，我们可以编写一个查询来返回已创建的实体。
以下返回文章及其对应的实体
MATCH (article:Article)
RETURN article.uri AS article,
[(article)-[r:HAS_ENTITY]->(e) | {entity: e.text, score: r.gcpEntityScore}] AS entities;| article | entities |
|---|---|
"/blog/pokegraph-gotta-graph-em-all/" |
[{score: 0.020393685, entity: "Neo4j"}, {score: 0.034420907, entity: "offices"}, {score: 0.0603245, entity: "tournaments"}, {score: 0.020393685, entity: "European"}, {score: 0.029095741, entity: "Mario Kart 8"}, {score: 0.12601112, entity: "Nintendo"}, {score: 0.13336793, entity: "friends"}, {score: 0.08861496, entity: "board games"}, {score: 0.143287, entity: "Switch"}, {score: 0.16441391, entity: "role playing games"}, {score: 0.17967656, entity: "card games"}] |
"https://en.wikipedia.org/wiki/Nintendo_Switch" |
[{score: 0.76108575, entity: "Nintendo Switch"}, {score: 0.07424594, entity: "Nintendo"}, {score: 0.015900765, entity: "home console"}, {score: 0.012772448, entity: "device"}, {score: 0.038113687, entity: "regions"}, {score: 0.07299799, entity: "Joy-Con Wheel"}] |
如果我们希望流式传输返回实体并对结果应用自定义逻辑，请参阅 apoc.nlp.gcp.entities.stream。