apoc.nlp.gcp.classify.stream

过程 Apoc 扩展

将文档分类为类别。

签名

apoc.nlp.gcp.classify.stream(source :: ANY?, config = {} :: MAP?) :: (node :: NODE?, value :: MAP?, error :: MAP?)

输入参数

名称	类型	默认
source	ANY?	null
config	MAP?	{}

名称

类型

默认

source

ANY?

null

config

MAP?

{}

输出参数

名称	类型
节点	NODE?
值	MAP?
错误 (error)	MAP?

名称

类型

节点

NODE?

值

MAP?

错误 (error)

MAP?

安装依赖

NLP 过程依赖于 Kotlin 和客户端库，这些库未包含在 APOC Extended 库中。

这些依赖项包含在 apoc-nlp-dependencies-2025.10.0-all.jar 中，可从发布页面下载。下载该文件后，应将其放入 plugins 目录并重启 Neo4j 服务器。

设置 API 密钥

您可以前往 console.cloud.google.com/apis/credentials 生成有权访问 Cloud Natural Language API 的 API 密钥。创建密钥后，我们可以填充并执行以下命令来创建一个包含这些详细信息的参数。

以下定义了 apiKey 参数

:param apiKey => ("<api-key-here>")

或者，我们可以将这些凭据添加到 apoc.conf 中，并使用静态值存储函数加载它们。

apoc.conf

apoc.static.gcp.apiKey=<api-key-here>

以下从 apoc.conf 中检索 GCP 凭据

RETURN apoc.static.getAll("gcp") AS gcp;

表 1. 结果
gcp
{apiKey: "<api-key-here>"}

使用示例

本节中的示例基于以下示例图

CREATE (:Article {
  uri: "/blog/pokegraph-gotta-graph-em-all/",
  body: "These days I’m rarely more than a few feet away from my Nintendo Switch and I play board games, card games and role playing games with friends at least once or twice a week. I’ve even organised lunch-time Mario Kart 8 tournaments between the Neo4j European offices!"
});

CREATE (:Article {
  uri: "https://en.wikipedia.org/wiki/Nintendo_Switch",
  body: "The Nintendo Switch is a video game console developed by Nintendo, released worldwide in most regions on March 3, 2017. It is a hybrid console that can be used as a home console and portable device. The Nintendo Switch was unveiled on October 20, 2016. Nintendo offers a Joy-Con Wheel, a small steering wheel-like unit that a Joy-Con can slot into, allowing it to be used for racing games such as Mario Kart 8."
});

我们可以使用此过程从 Article 节点中提取分类。我们想要分析的文本存储在节点的 body 属性中，因此我们需要通过 nodeProperty 配置参数来指定它。

以下代码为 Pokemon 文章流式传输分类

MATCH (a:Article {uri: "/blog/pokegraph-gotta-graph-em-all/"})
CALL apoc.nlp.gcp.classify.stream(a, {
  key: $apiKey,
  nodeProperty: "body"
})
YIELD value
UNWIND value.categories AS category
RETURN category;

表 2. 结果
category
{name: "/Games", confidence: 0.91}

我们只返回了一个分类。然后，我们可以应用一条 Cypher 语句，为每个分类创建一个节点，并从这些节点中的每一个创建一条指向 Article 节点的 CATEGORY 关系。

以下代码为 Pokemon 文章流式传输分类，并为每个分类创建节点

MATCH (a:Article {uri: "/blog/pokegraph-gotta-graph-em-all/"})
CALL apoc.nlp.gcp.classify.stream(a, {
  key: $apiKey,
  nodeProperty: "body"
})
YIELD value
UNWIND value.categories AS category
MERGE (c:Category {name: category.name})
MERGE (a)-[:CATEGORY]->(c)

如果我们想要自动创建分类图，请参阅 apoc.nlp.gcp.classify.graph。