LIMIT

LIMIT 用于限制返回的行数。

LIMIT 接受任何求值为正 INTEGER（整数）的表达式，且该表达式不能包含任何变量，也不能引用节点或关系。

Neo4j 不保证 LIMIT 生成结果的顺序。唯一能保证特定行顺序的子句是 ORDER BY。

示例图

以下图表用于下方的示例

Example graph connecting Person nodes

要重新创建它，请在空的 Neo4j 数据库中运行以下查询

CREATE
  (andy: Person {name: 'Andy'}),
  (bernard: Person {name: 'Bernard'}),
  (charlotte: Person {name: 'Charlotte'}),
  (david: Person {name: 'David'}),
  (erika: Person {name: 'Erika'}),
  (andy)-[:KNOWS]->(bernard),
  (andy)-[:KNOWS]->(charlotte),
  (andy)-[:KNOWS]->(david),
  (andy)-[:KNOWS]->(erika)

示例

示例 1. 返回行的有限子集

若要返回行的有限子集，请使用此语法：

查询
MATCH (n)
RETURN n.name
ORDER BY n.name
LIMIT 3

通过示例查询限制为 3 行。

结果
n.name

"Andy"

"Bernard"

"Charlotte"

行：3
示例 2. 在 LIMIT 中使用表达式来返回行的子集

LIMIT 接受任何求值为正整数的表达式，前提是它可以被静态计算（即在查询运行前计算）。

查询
MATCH (n)
RETURN n.name
ORDER BY n.name
LIMIT 1 + toInteger(3 * rand())

限制 1 行加上随机的 0、1 或 2 行。因此随机限制为 1、2 或 3 行。

结果
n.name

"Andy"

"Bernard"

"Charlotte"

行：3

LIMIT 与副作用

如果 LIMIT 与副作用（如 CREATE、DELETE 或 SET）位于同一个查询部分，则 LIMIT 不会阻止这些副作用的发生。

查询
CREATE (n)
RETURN n
LIMIT 0

此查询不返回任何内容，但会创建一个节点

结果

(空结果)

行数：0
创建的节点：1
查询
MATCH (n {name: 'A'})
SET n.age = 60
RETURN n
LIMIT 0

此查询不返回任何内容，但会写入一个属性

结果

(空结果)

行数：0
已设置属性：1

如果我们想限制更新的数量，可以使用 WITH 子句拆分查询

查询
MATCH (n)
WITH n ORDER BY n.name LIMIT 1
SET n.locked = true
RETURN n
ORDER BY n.name

在一个节点上写入 locked 属性并返回该节点

结果
n

{locked:true,name:"Andy",age:60}

行：1
已设置属性：1

将 LIMIT 用作独立子句

LIMIT 可以作为独立子句使用，也可以与 ORDER BY 或 SKIP/OFFSET 结合使用。

LIMIT 的独立使用
MATCH (n)
LIMIT 2
RETURN collect(n.name) AS names
结果
names

["Andy", "Bernard"]

行：1

以下查询按 name 降序排列所有节点，跳过前两行，并将结果限制为两行。然后它将结果 collect（收集）到一个列表中。

LIMIT 与 ORDER BY 和 SKIP 结合使用
MATCH (n)
ORDER BY n.name DESC
SKIP 2
LIMIT 2
RETURN collect(n.name) AS names
结果
names

["David", "Charlotte"]

行：1